Globals out of date for subsequent SAY block?

[Bleepbloop]

Hey all.

A pattern I'm wanting to use pretty often is to set a global in a transition, then make one or more transitions in the subsequent SAY block depend on it. Example:

Code: [Select]

IF ~~ FirstSayBlock
    SAY ~Some text~

    ++ ~Some text~ DO ~IncrementGlobal("SomeGlobalVariable", "GLOBAL", 1)~ + SecondSayBlock
END

IF ~~ SecondSayBlock
    SAY ~Some text~
    IF ~GlobalLT("SomeGlobalVariable", "GLOBAL", 10)~ THEN GOTO ThirdSayBlock
    IF ~GlobalGT("SomeGlobalVariable", "GLOBAL", 9)~ THEN GOTO FourthSayBlock
END

However, the above doesn't seem to work properly, as I don't get SomeGlobalVariable's new value when the transitions in SecondSayBlock are evaluated.

The only workaround I've found is to spread SecondSayBlock out by using the shorthand chaining syntax. This seems to work:

Code: [Select]

IF ~~ FirstSayBlock
    SAY ~Some text~

    ++ ~Some text~ DO ~IncrementGlobal("SomeGlobalVariable", "GLOBAL", 1)~ + SecondSayBlock
END

IF ~~ SecondSayBlock
    SAY ~Some text~ = ~Some more text~
    IF ~GlobalLT("SomeGlobalVariable", "GLOBAL", 10)~ THEN GOTO ThirdSayBlock
    IF ~GlobalGT("SomeGlobalVariable", "GLOBAL", 9)~ THEN GOTO FourthSayBlock
END

Is there a nicer way to do this?

[Argent77]

Script action in dialogs are executed with a delay. Iirc, you need at least two transitions before the variable is updated correctly. However, if you code your mod only for the Enhanced Editions then you can add a flag to the transition to indicate that it should be executed immediately. It should work for all script actions listed in INSTANT.IDS (and possibly some more).

In your example add the keyword "FLAGS" with the respective numeric value (bit 9 = 512) to the reply entry:

Code: [Select]

IF ~~ FirstSayBlock
    SAY ~Some text~
    ++ ~Some text~ DO ~IncrementGlobal("SomeGlobalVariable", "GLOBAL", 1)~ FLAGS 512 + SecondSayBlock
END

IF ~~ SecondSayBlock
    SAY ~Some text~
    IF ~GlobalLT("SomeGlobalVariable", "GLOBAL", 10)~ THEN GOTO ThirdSayBlock
    IF ~GlobalGT("SomeGlobalVariable", "GLOBAL", 9)~ THEN GOTO FourthSayBlock
END


Btw, this board has been pretty quiet for some time. I'd suggest to ask about modding-related topics in the G3 Forums which is more active.

[Bleepbloop]

Wow, that is awesome, thank you. I did not expect an outright solution for this. Now to roll up my sleeves and retrofit it into my code.

Btw yeah my mod is for BG2 EE only. And thanks for the tip about the G3 forums.