During EE development, a number of cut banters were found. I'm way, way behind on UB (or ARP) development so I have no idea if these have already been found and enabled already.
Aerie and Jan banter about Jan's great-grandfather slaying a dragon:
ADD_STATE_TRIGGER BAERIE 44 ~InParty("Jan") See("Jan") !StateCheck("Jan",STATE_SLEEPING) Global("CDAerieJanBanter","LOCALS",0)~
ADD_TRANS_ACTION BAERIE BEGIN 44 END BEGIN END ~SetGlobal("CDAerieJanBanter","LOCALS",1)~
Aerie and Minsc talk about the forest:
ADD_STATE_TRIGGER BAERIE 76 ~InParty("Minsc") See("Minsc") !StateCheck("Minsc",STATE_SLEEPING) Global("CDAerieMinscBanter","LOCALS",0) AreaType(FOREST)~
ADD_TRANS_ACTION BAERIE BEGIN 76 END BEGIN END ~SetGlobal("CDAerieMinscBanter","LOCALS",1)~
Haer'Dalis and Mazzy have a brief aside--very brief, two lines--about her ferocity.
ADD_STATE_TRIGGER BHAERDA 2 ~InParty("Mazzy") See("Mazzy") !StateCheck("Mazzy",STATE_SLEEPING) Global("CDHaerdalisMazzyBanter","LOCALS",0)~
ADD_TRANS_ACTION BHAERDA BEGIN 2 END BEGIN END ~SetGlobal("CDHaerdalisMazzyBanter","LOCALS",1)~
Valygar and Korgan discuss dwarves:
ADD_STATE_TRIGGER BVALYGA 65 ~InParty("Korgan") See("Korgan") !StateCheck("Korgan",STATE_SLEEPING) Global("CDValygarKorganBanter","LOCALS",0)~
ADD_TRANS_ACTION BVALYGA BEGIN 65 END BEGIN END ~SetGlobal("CDValygarKorganBanter","LOCALS",1)~
Viconia packs four taunts in two lines with Mazzy:
ADD_STATE_TRIGGER BVICONI 7 ~InParty("Mazzy") See("Mazzy") !StateCheck("Mazzy",STATE_SLEEPING) Global("CDViconiaMazzyBanter","LOCALS",0)~
ADD_TRANS_ACTION BVICONI BEGIN 7 END BEGIN END ~SetGlobal("CDViconiaMazzyBanter","LOCALS",1)~
Viconia doesn't trust Yoshimo:
ADD_STATE_TRIGGER BVICONI 8 ~InParty("Yoshimo") See("Yoshimo") !StateCheck("Yoshimo",STATE_SLEEPING) Global("CDViconiaYoshimoBanter","LOCALS",0)~
ADD_TRANS_ACTION BVICONI BEGIN 8 END BEGIN END ~SetGlobal("CDViconiaYoshimoBanter","LOCALS",1)~
Viconia and Jan briefly exchange barbs:
ADD_STATE_TRIGGER BVICONI 24 ~InParty("Jan") See("Jan") !StateCheck("Jan",STATE_SLEEPING) Global("CDViconiaJanBanter","LOCALS",0)~
ADD_TRANS_ACTION BVICONI BEGIN 24 END BEGIN END ~SetGlobal("CDViconiaJanBanter","LOCALS",1)~
Yoshimo praises Boo's battle prowess:
REPLACE_STATE_TRIGGER BYOSHIM 71 ~InParty("Minsc") See("Minsc") HPLT("Minsc",20) !StateCheck("Minsc",STATE_SLEEPING) CombatCounter(0) Global("BYoshimo13","LOCALS",1)~ // triggers present, but commented out and false'd
This one also requires some yoshimo.bcs touchups:
IF
InParty(Myself)
!StateCheck(Myself,STATE_SLEEPING)
InParty("Minsc")
See("Minsc")
HPLT("Minsc",20)
!StateCheck("Minsc",STATE_SLEEPING)
CombatCounter(0)
Global("BYoshimo13","LOCALS",0)
THEN
RESPONSE #100
SetGlobal("BYoshimo13","LOCALS",1)
Interact("Minsc")
END
A couple of NPCs have banters if one dies and was resurrected, so these also require a little scripting. Boo--certainly not Minsc!--was scared about losing Mazzy, and Yoshimo is happy to see Aerie's return:
ADD_STATE_TRIGGER BMINSC 30 ~InParty("Mazzy") See("Mazzy") !StateCheck("Mazzy",STATE_SLEEPING) Global("CDMinscMazzyBanter","LOCALS",2)~
ADD_TRANS_ACTION BMINSC BEGIN 30 END BEGIN END ~SetGlobal("CDMinscMazzyBanter","LOCALS",3)~
ADD_STATE_TRIGGER BYOSHIM 0 ~InParty("Aerie") See("Aerie") !StateCheck("Aerie",STATE_SLEEPING) Global("CDYoshimoAerieBanter","LOCALS",2)~
ADD_TRANS_ACTION BYOSHIM BEGIN 0 END BEGIN END ~SetGlobal("CDYoshimoAerieBanter","LOCALS",3)~
Also requires some minsc.bcs scripting:
// restored minsc-mazzy banter
IF
InParty(Myself)
InParty("Mazzy")
Dead("Mazzy")
Global("CDMinscMazzyBanter","LOCALS",0)
THEN
RESPONSE #100
SetGlobal("CDMinscMazzyBanter","LOCALS",1)
END
IF
InParty(Myself)
!StateCheck(Myself,STATE_SLEEPING)
InParty("Mazzy")
See("Mazzy")
!StateCheck("Mazzy",STATE_SLEEPING)
!Dead("Mazzy")
Global("CDMinscMazzyBanter","LOCALS",1)
THEN
RESPONSE #100
SetGlobal("CDMinscMazzyBanter","LOCALS",2)
Interact("Mazzy")
END
...and some yoshimo.bcs scripting:
IF
InParty(Myself)
InParty("Aerie")
Dead("Aerie")
Global("CDYoshimoAerieBanter","LOCALS",0)
THEN
RESPONSE #100
SetGlobal("CDYoshimoAerieBanter","LOCALS",1)
END
IF
InParty(Myself)
!StateCheck(Myself,STATE_SLEEPING)
InParty("Aerie")
See("Aerie")
!StateCheck("Aerie",STATE_SLEEPING)
!Dead("Aerie")
Global("CDYoshimoAerieBanter","LOCALS",1)
THEN
RESPONSE #100
SetGlobal("CDYoshimoAerieBanter","LOCALS",2)
Interact("Aerie")
END