CLONE_EFFECT... to make *two* cloned effects?

[subtledoctor]

I'm cloning some priest spells to be one level lower for certain kits; and to make sure that all spells and items that interact with the original spell also interact with the modified spell, I use a modified CLONE_EFFECT to add the new spell to all effects that use opcode 206, 318, 321, and 324.  Something like this:

Code: [Select]

COPY_EXISTING_REGEXP GLOB ~.*\.spl~ ~override~
   LPF CLONE_EFFECT INT_VAR match_opcode=206 STR_VAR resource=~lowspell~ END
Now, say I want to make another clone of the spell, at a higher level, or something.  If I do this:

Code: [Select]

COPY_EXISTING_REGEXP GLOB ~.*\.spl~ ~override~
   LPF CLONE_EFFECT INT_VAR match_opcode=206 STR_VAR resource=~lowspell~ END
   LPF CLONE_EFFECT INT_VAR match_opcode=206 STR_VAR resource=~highspell~ END...I end up with 4 206 effects, because the macro will run once and clone the 206 effect, and then run again, find *two* 206 effects, and clone both of them.

I just want 3 206 effects: one for the original spell, and one for each new spell.  Can I run CLONE_EFFECT just once to derive two clones of the 206 effect?  Can I edit some part of the CLONE_EFFECT macro to achieve this?  (@CamDawg?)  It would be a nice way to make my code more efficient.  Right now this routine take about 60 seconds to run... which is a long time in Weidu terms (setting aside SCS).  If I could get that down to 30-40 seconds, it would be a noticeable improvement.

[Wisp]

If you want to make CLONE_EFFECT stop after finding a match, that feature already exists.

INT_VAR multi_match to the number of effects to clone in the active stack. If you just want to match the first effect and have the function stop, use 1. Otherwise the function will continue matching until the number of cloned effects matches this value. The function will always make at least one change (e.g. 0 or negative values are treated as 1). (default is 999).

If you place the cloned effect after the original one, CLONE_EFFECT will also only clone the original effect on the second pass.

[CamDawg]

^^ What Wisp said, or define a match_resource so it doesn't clone every stray 206 it finds.

[subtledoctor]

Can't use multi_match, because some spells/items might have two 206 effects, in which case I want to clone them both twice and end up with six. (But not eight.)

Could match_resource take a negative? Like,

CLONE_EFFECT STR match_resource = NOT ~[some regexp]~ ...?

[CamDawg]

Each CLONE call is an independent action; setting multi_match = 1 will not affect future calls.

Code: [Select]

COPY_EXISTING_REGEXP GLOB ~.*\.spl~ ~override~
   LPF CLONE_EFFECT INT_VAR match_opcode=206 multi_match = 1 STR_VAR resource=~lowspell~ END
   LPF CLONE_EFFECT INT_VAR match_opcode=206 multi_match = 1 STR_VAR resource=~highspell~ END
The first CLONE runs, finds the first 206, makes one copy, and stops. The second CLONE runs, finds the first 206, makes one copy, and stops. Now you have the original 206, one for highspell, and one for lowspell. Alternatively

Code: [Select]

COPY_EXISTING_REGEXP GLOB ~.*\.spl~ ~override~
   LPF CLONE_EFFECT INT_VAR match_opcode=206 STR_VAR resource=~lowspell~ match_resource = ~originalspell~ END
   LPF CLONE_EFFECT INT_VAR match_opcode=206 STR_VAR resource=~highspell~ match_resource = ~originalspell~ END
Now it runs, finds the existing spell protection, makes a clone for lowspell. The second one runs, ignores the new 206 for lowspell, finds the original 206, and clones it into a new 206 for highspell.

Both ways end up with the original 206, one for lowspell, and one for highspell.

If you're doing a ton of these, probably the best way would be to simply make an array of new_spell => original and then iterate through it with PHP_EACH. E.g.

Code: [Select]

ACTION_DEFINE_ASSOCIATIVE_ARRAY cd_map_newspells BEGIN
  low_aid=> sppr201
  high_aid=> sppr201
  low_ani=> sppr301
  high_ani=> sppr301
END

COPY_EXISTING_REGEXP GLOB ~.*\.spl~ ~override~
                          ~.*\.itm~ ~override~
                          ~.*\.cre~ ~override~
  PHP_EACH cd_map_newspells AS new => old BEGIN
    PATCH_FOR_EACH op IN 206 318 321 324 BEGIN
      LPF CLONE_EFFECT INT_VAR match_opcode = op STR_VAR resource = EVAL ~%new%~ match_resource = EVAL ~%old%~ END
    END
  END
  BUT_ONLY
edit: missing a BEGIN

[subtledoctor]

Yeah but if I want it to work on every spell it's not really feasible to use an array, or to use the match_resource parameter.  I suppose I could build an array, by iterating through every row in SPELL.IDS... but that still wouldn't catch mod spells that aren't ADD_SPELL'd. 

Eh, it's not worth spending too much energy on this, the mod works right now (if slightly messily) and even in its current inefficient form it still installs in like 1/20th the time that SCS takes...