Real Timers in scripting

[Diana]

I've used the in game timer command successfully in scipting but  have a question regarding "Real Timers".  For example:

RealSetGlobalTimer("Nightmare","GLOBAL",2200)

I'm assuming this expires after 3+ hours of real life play.  Question is - does that play have to be continuous or does the game remember how much time elapsed when I saved the game and then reloaded it to resume playing?  Does the script  (1) begin the countdown from when I reload or (2) does the timer start all over again i.e. being set back to 2200?

Thanks.

[Bons]

does the game remember how much time elapsed when I saved the game and then reloaded it to resume playing?  Does the script  (1) begin the countdown from when I reload

Yes. The savegame will include the status of your timer, so when you load, the realtimer countdown to expiration will resume from that point. Also, the timer is in seconds, so 2200 will amount to about 35 minutes of real life play.

[Galactygon]

I also beleieve that the RealTimer also ignores game pauses, meaning that it may elapse if you pause the game and leave it like that for the appropriate time.

I may be wrong, though.

-Galactygon

[Ghreyfain]

I also beleieve that the RealTimer also ignores game pauses, meaning that it may elapse if you pause the game and leave it like that for the appropriate time.

I may be wrong, though.

-Galactygon

Nope, you're correct.

[Grim Squeaker]

Yes, because that's REAL time.

[Diana]

Thanks all.  Since I've been playing more than 35 minutes and it HASN'T expired and activated the  block where the test is for its expiration I have to check and see what's gone wrong in the .BCS and the .D file

[Ghreyfain]

That's why for testing one should use timers of about 1 second.   Or use the CLUAConsole:SetGlobal("MyTimer","GLOBAL",1) command to speed up the timer.

[Diana]

Call me super frustrated - and thanks for the test on how to check for the timer  - most of the documentation I've been reading wasn't so clear cut.

Anyhow - I cannot for the life of me figure why the second dream doesn't kick in:

From the .bcs file

IF
  PartyRested()
  IfValidForPartyDialogue("D#Silver")
  GlobalGT("SilverEvil","GLOBAL",0)
  Global("SilDream1","GLOBAL",0)
THEN
  RESPONSE #100
    SetGlobal("SilDream1","GLOBAL",1)
    Dialog(Player1)
    RealSetGlobalTimer("SilNightmer","GLOBAL",2200)
END

Comments - she makes her speech and after the coding in the J.D file Sildream1 Global was set to 2.

IF
  PartyRested()
  RealGlobalTimerExpired("SilNightmer","GLOBAL")
  IfValidForPartyDialogue("D#Silver")
  Global("SilDream1","GLOBAL",2)
THEN
  RESPONSE #100
    SetGlobal("SilDream1","GLOBAL",3)
    Dialog(Player1)
    RealSetGlobalTimer("SilNightmer","GLOBAL",2200)
END

This is my problem - I'm never getting the block above to execute though Sildream1 is 2.  Somehow the RealSetGlobalTimer isn't working!

IF
  PartyRested()
  RealGlobalTimerExpired("SilNightmer","GLOBAL")
  IfValidForPartyDialogue("D#Silver")  // D#Silver
  Global("SilDream1","GLOBAL",4)
THEN
  RESPONSE #100
    SetGlobal("D#SilDream1","GLOBAL",5)
    Dialog(Player1)
END

The "J.D" file

IF WEIGHT #0 ~Global("SilDream1","GLOBAL",1)~ THEN DSildream1
  SAY @112
  IF ~~ DO ~SetGlobal("SilDream1","GLOBAL",2)~ GOTO Sildream2
END

IF ~~ Sildream2
  SAY @113
  IF ~!InParty("Edwin")~ REPLY @116 EXIT
  IF ~!InParty("Edwin")~ REPLY @117 EXIT
  IF ~InParty("Edwin")~ EXTERN BEdwin Sildream3
END

Comments - She says her @113 and exits the dialog because Edwin not in party.  SilDream1 is set to 2.

IF ~~ Sildream4
  SAY @115
  IF ~~ REPLY @116 EXIT
  IF ~~ REPLY @117 EXIT
END

IF WEIGHT #0 ~Global("SilDream1","GLOBAL",3)~ Sildream5
  SAY @118 = @119 = @120 = @121 = @122
  IF ~InParty("Edwin")~ REPLY @123 DO ~SetGlobal("SilDream1","GLOBAL",4)~ EXTERN BEdwin Sildream6
  IF ~!InParty("Edwin")~ REPLY @125 DO ~SetGlobal("SilDream1","GLOBAL",4)~ EXIT
END

IF WEIGHT #0 ~Global("SilDream1","GLOBAL",5)~ Sildream7
  SAY @126 = @127
  IF ~~ REPLY @128 DO ~SetGlobal("SilDream1","GLOBAL",6)~ EXIT
END

APPEND Bedwin

IF ~~ Sildream6
  SAY @124
  IF ~~ EXIT
END

IF ~~ Sildream3
  SAY @114
  IF ~~ EXTERN D#Silver Sildream4
END
END

I hate to ask it - but what am I doing wrong??

[Kismet]

Try setting the timer before you start the dialog.

 RESPONSE #100
    SetGlobal("SilDream1","GLOBAL",3)
    RealSetGlobalTimer("SilNightmer","GLOBAL",2200)
    Dialog(Player1)

[Grim Squeaker]

Try setting the timer before you start the dialog.

 RESPONSE #100
    SetGlobal("SilDream1","GLOBAL",3)
    RealSetGlobalTimer("SilNightmer","GLOBAL",2200)
    Dialog(Player1)

Yeah, I think that should do it.  I think engine 'forgets' any actions it was meant to perform after the dialogue is resolved.

[Diana]

Thanks - I'll give it a try after work.

[Diana]

Thanks all....it works!