Author Topic: Scar quest extention extention (for v13)  (Read 3765 times)

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Scar quest extention extention (for v13)
« on: October 04, 2010, 03:22:23 PM »
This is what I am planning for the next release. in short: Added reply options so quests can be finished if talked to Scar too soon, make Duke Elhan wait so the PC can finish the Scar quests if accidentally talking to him, and extending the Sewer quest not only with the daughter's body (current UB material) but also by making the ring a unique item. Any comments welcome, especially if you see code that might need improving.
EDIT: The text will be proofread, of course. Edit away.



REPLACE_STATE_TRIGGER %tutu_var%ARKION 6 ~Global("HelpArkion","GLOBAL",1)~

REPLACE %tutu_var%ARKION
IF ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC80")~ THEN BEGIN 3
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC80")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

APPEND %tutu_var%ARKION
IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC79")~ THEN BEGIN EitherBody
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC79")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC79") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END

IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("UBFEBODY")~ THEN BEGIN NobleBody
  SAY @16
  IF ~~ THEN EXIT
END
END





/* Extentions of the Scar quest regarding playability:
- if the PC declines to say his name or to work for Scar at the bridge, he can now do so when he sees Scar in front of the FF headquarters.
-talking to Eltan directly won't kill Scar's quests: The PC has the choice to finish his work for Scar, first. Eltan's quest will work as usual when Scar brings the PC to him.

*/


/* LORD ELTAN
 If the PC talked to Lord Eltan directly, Scar will disappear and all his quests will be lost. Not any more: */

REPLACE_STATE_TRIGGER %tutu_var%DELTAN 0 ~~

APPEND %tutu_var%DELTAN
IF WEIGHT #-1
~Global("HelpEltan","GLOBAL",0)~ THEN not_yet
SAY ~You... I think I heard of you. You might be of service to me and this city. Will you hear me out?~
+ ~GlobalLT("ScarMission","GLOBAL",5)~ + ~I am sorry, but I am doing investigations for your Second in Command I would like to finish, first.~ EXIT
+ ~GlobalLT("ScarMission","GLOBAL",5)~ + ~Yes, tell me what you want. I am sure Scar can deal with his problems himself.~ + 0
+ ~GlobalGT("ScarMission","GLOBAL",4)~ + ~Just a moment, I have to finish something, first.~ EXIT
+ ~GlobalGT("ScarMission","GLOBAL",4)~ + ~Well, then speak.~ + 0
END
END //APPEND




/* PC can tell Scar who s/he is later
- if the PC declines to say his name or to work for Scar at the bridge, he can now do so when he sees Scar in front of the FF headquarters.*/


ADD_TRANS_ACTION %tutu_var%SCAR BEGIN 1 END BEGIN END ~SetGlobal("UB_ScarMission","GLOBAL",1)~

ADD_TRANS_ACTION %tutu_var%SCAR BEGIN 3 END BEGIN END ~SetGlobal("UB_ScarMission","GLOBAL",2)~

EXTEND_BOTTOM %tutu_var%SCAR 19
+ ~Global("UB_ScarMission","GLOBAL",1)~ + ~Not so fast. Let me first tell you that I am indeed the one involved in the clearing of the Nashkel mines.~ DO ~SetGlobal("UB_ScarMission","GLOBAL",0)~ + 2
+ ~Global("UB_ScarMission","GLOBAL",2)~ + ~Just a minute. You said something about help you would need. I am interested in working for you now.~ DO ~SetGlobal("UB_ScarMission","GLOBAL",0)~ + 4
END



/* If the PC talks to Scar again before defeating the doppelgangers in the seven suns, he will lose the job: not any more

BGT already adds this!

*/

EXTEND_BOTTOM %tutu_var%SCAR 14
+ ~GlobalLT("KilledDopple","GLOBAL",5)~ + ~I am not finished there yet.~ + more_battle
END

APPEND %tutu_var%SCAR
IF ~~ THEN more_battle
SAY ~Please go back and fight those creatures. I won't be at ease until I know the Seven Suns building is cleansed and no more people in danger.~
IF ~~ THEN EXIT
END

END //APPEND


/* If the PC talks to Scar before killing the Oger mage, the quest will be gone: Not any more. */

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN 31 END
BEGIN 0 END
~SetGlobal("ScarMission","GLOBAL",4)~ ~~


EXTEND_BOTTOM %tutu_var%Scar 31
+ ~!Dead("SewerOgre")~ + ~I give up on this one.~ + 37
+ ~!Dead("SewerOgre")~ + ~We are still on it.~ + 36
END



/* COSMETIC TWEAK State 10 misses some polite answer e.g. for paladins */

 
EXTEND_BOTTOM %tutu_var%Scar 10
++ ~Of course we will go back and fight those monsters!~ + 12
END




/* another addition: If the PC doesn't have the ring of the girl the first time he reports he won't have the chance to bring it later: not any more.
Also tweaked to make the ring unique. 
Combined with the "bring the dead girl's body" quest extention.


Unique ring: UBSCARIN.itm in AR0226 ESewers */

REPLACE_TRANS_TRIGGER %tutu_var%Scar BEGIN 32 END BEGIN 1 END ~PartyHasItem("%tutu_var%RING19")~ ~False()~


EXTEND_BOTTOM %tutu_var%Scar 32
  IF ~PartyHasItem("UBSCARIN")~ THEN REPLY ~Yes we did, we'll happily return it.~ GOTO 34_UB
+ ~!PartyHasItem("UBSCARIN")~ + ~I will go again and have a closer look.~ DO ~SetGlobal("UBScarRingFetch","LOCALS",1)~ + scar_ring
+ ~PartyHasItem("UBFEBODY") PartyHasItem("UBSCARIN")~ + ~I think I also found her body.~ DO ~TakePartyItem("UBSCARIN")~ + AlreadyHaveBody
+ ~PartyHasItem("UBFEBODY") !PartyHasItem("UBSCARIN")~ + ~I didn't find a ring but what appears to be her body.~ DO ~TakePartyItem("UBFEBODY")~ + scar_only_body
END

APPEND %tutu_var%Scar
IF ~~ THEN scar_only_body
SAY ~You have done well! This will help the Sashenstars to find some peace. Still, I am sure it would help them to have the ring to remember their loved one.~
++ ~I will go again and have a closer look.~ DO ~SetGlobal("UBScarRingFetch","LOCALS",2)~ + scar_ring
  IF ~~ THEN REPLY ~I really don't have time for that now.~ GOTO 33
END


IF ~~ THEN scar_ring
SAY ~If you would take the time, I am sure the Sashenstar family will be more than grateful.~
IF ~~ THEN EXIT
END


IF WEIGHT #0 ~GlobalGT("UBScarRingFetch","LOCALS",0)~ THEN BEGIN RingFetchQuestReturn
  SAY ~It's good to see you again, how have things gone?~
+ ~Dead("SewerOgre") !PartyHasItem("UBSCARIN")~ + ~I am still searching for possessions of the victims.~ EXIT
+ ~Global("UBScarRingFetch","LOCALS",1) PartyHasItem("UBSCARIN")~ + ~We found a ring that looks special.~ DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 34_UB
+ ~Global("UBScarRingFetch","LOCALS",2) PartyHasItem("UBSCARIN")~ + ~We found a ring that looks special.~ DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 34
++ ~I give up on this one.~ DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 33
END

END //APPEND



REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN 34 END
BEGIN 0 END
~TakePartyItem("%tutu_var%RING19")~ ~TakePartyItem("UBSCARIN")~


APPEND %tutu_var%SCAR
IF ~~ THEN BEGIN 34_UB
  SAY @1
  IF ~PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @2 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @3 GOTO NoWay
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @4 GOTO WillReturnBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @5 GOTO NoWay
END

IF ~~ THEN BEGIN AlreadyHaveBody
  SAY @6
  COPY_TRANS %tutu_var%SCAR 34
END

IF ~~ THEN BEGIN NoWay
  SAY @7
  COPY_TRANS %tutu_var%SCAR 33
END

IF ~~ THEN BEGIN WillReturnBody
  SAY @8
  IF ~~ THEN DO ~SetGlobal("ScarBodyFetch","GLOBAL",1)~ EXIT
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",1)~ THEN BEGIN BodyFetchQuestReturn
  SAY @9
  IF ~PartyHasItem("UBFEBODY")~ THEN REPLY @10 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN REPLY @11 GOTO NoBodyYet
  IF ~~ THEN REPLY @12 GOTO NoWay
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",2)
PartyHasItem("UBFEBODY")~ THEN BEGIN ChangedMind
  SAY @13
  IF ~~ THEN REPLY @14 GOTO AlreadyHaveBody
END

IF ~~ THEN BEGIN NoBodyYet
  SAY @15
  IF ~~ THEN EXIT
END
END

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN AlreadyHaveBody END
BEGIN 0 END
~TakePartyItem("%tutu_var%RING19")~ ~TakePartyItem("UBFEBODY") SetGlobal("ScarBodyFetch","GLOBAL",3)~

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN NoWay END
BEGIN 0 END
~GiveGoldForce(1000)
AddexperienceParty(2000)~
~GiveGoldForce(500)
AddexperienceParty(3000)
SetGlobal("ScarBodyFetch","GLOBAL",2)~
« Last Edit: October 06, 2010, 03:48:48 AM by jastey »

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Re: Scar quest extention extention (for v13)
« Reply #1 on: October 05, 2010, 05:10:40 PM »
Edited the first post with the debugged version. If no-one has any objections, this will be the quest extention. Next is traifying, proofreading, and call for translations.

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Re: Scar quest extention extention (for v13)
« Reply #2 on: October 06, 2010, 06:57:02 AM »
Traiyfied version:


REPLACE_STATE_TRIGGER %tutu_var%ARKION 6 ~Global("HelpArkion","GLOBAL",1)~

REPLACE %tutu_var%ARKION
IF ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC80")~ THEN BEGIN 3
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC80")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

APPEND %tutu_var%ARKION
IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC79")~ THEN BEGIN EitherBody
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC79")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC79") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END

IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("UBFEBODY")~ THEN BEGIN NobleBody
  SAY @16
  IF ~~ THEN EXIT
END
END





/* Extentions of the Scar quest regarding playability:
- if the PC declines to say his name or to work for Scar at the bridge, he can now do so when he sees Scar in front of the FF headquarters.
-talking to Eltan directly won't kill Scar's quests: The PC has the choice to finish his work for Scar, first. Eltan's quest will work as usual when Scar brings the PC to him.

*/


/* LORD ELTAN
 If the PC talked to Lord Eltan directly, Scar will disappear and all his quests will be lost. Not any more: */

REPLACE_STATE_TRIGGER %tutu_var%DELTAN 0 ~~

APPEND %tutu_var%DELTAN
IF WEIGHT #-1
~Global("HelpEltan","GLOBAL",0)~ THEN not_yet
SAY @17
+ ~GlobalLT("ScarMission","GLOBAL",5)~ + @18 EXIT
+ ~GlobalLT("ScarMission","GLOBAL",5)~ + @19 + 0
+ ~GlobalGT("ScarMission","GLOBAL",4)~ + @20 EXIT
+ ~GlobalGT("ScarMission","GLOBAL",4)~ + @21 + 0
END
END //APPEND




/* PC can tell Scar who s/he is later
- if the PC declines to say his name or to work for Scar at the bridge, he can now do so when he sees Scar in front of the FF headquarters.*/


ADD_TRANS_ACTION %tutu_var%SCAR BEGIN 1 END BEGIN END ~SetGlobal("UB_ScarMission","GLOBAL",1)~

ADD_TRANS_ACTION %tutu_var%SCAR BEGIN 3 END BEGIN END ~SetGlobal("UB_ScarMission","GLOBAL",2)~

EXTEND_BOTTOM %tutu_var%SCAR 19
+ ~Global("UB_ScarMission","GLOBAL",1)~ + @22 DO ~SetGlobal("UB_ScarMission","GLOBAL",0)~ + 2
+ ~Global("UB_ScarMission","GLOBAL",2)~ + @23 DO ~SetGlobal("UB_ScarMission","GLOBAL",0)~ + 4
END



/* If the PC talks to Scar again before defeating the doppelgangers in the seven suns, he will lose the job: not any more

BGT already adds this!

*/

EXTEND_BOTTOM %tutu_var%SCAR 14
+ ~GlobalLT("KilledDopple","GLOBAL",5)~ + @24 + more_battle
END

APPEND %tutu_var%SCAR
IF ~~ THEN more_battle
SAY @25
IF ~~ THEN EXIT
END

END //APPEND


/* If the PC talks to Scar before killing the Oger mage, the quest will be gone: Not any more. */

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN 31 END
BEGIN 0 END
~SetGlobal("ScarMission","GLOBAL",4)~ ~~


EXTEND_BOTTOM %tutu_var%Scar 31
+ ~!Dead("SewerOgre")~ + @26 + 37
+ ~!Dead("SewerOgre")~ + @27 + 36
END



/* COSMETIC TWEAK States 2 and 10 miss some polite answer e.g. for paladins */

EXTEND_BOTTOM %tutu_var%Scar 2
++ @21 + 4
END

EXTEND_BOTTOM %tutu_var%Scar 10
++ @28 + 12
END




/* another addition: If the PC doesn't have the ring of the girl the first time he reports he won't have the chance to bring it later: not any more.
Also tweaked to make the ring unique. 
Combined with the existing (v12) "bring the dead girl's body" quest extention.


New custom ring: UBSCARIN.itm in AR0226 ESewers */

REPLACE_TRANS_TRIGGER %tutu_var%Scar BEGIN 32 END BEGIN 1 END ~PartyHasItem("%tutu_var%RING19")~ ~False()~


EXTEND_BOTTOM %tutu_var%Scar 32
  IF ~PartyHasItem("UBSCARIN")~ THEN REPLY @29 GOTO 34_UB
+ ~!PartyHasItem("UBSCARIN")~ + @30 DO ~SetGlobal("UBScarRingFetch","LOCALS",1)~ + scar_ring
+ ~PartyHasItem("UBFEBODY") PartyHasItem("UBSCARIN")~ + @31 DO ~TakePartyItem("UBSCARIN")~ + AlreadyHaveBody
+ ~PartyHasItem("UBFEBODY") !PartyHasItem("UBSCARIN")~ + @32 DO ~TakePartyItem("UBFEBODY")~ + scar_only_body
END

APPEND %tutu_var%Scar
IF ~~ THEN scar_only_body
SAY @33
++ @30 DO ~SetGlobal("UBScarRingFetch","LOCALS",2)~ + scar_ring
  IF ~~ THEN REPLY @34 GOTO 33
END


IF ~~ THEN scar_ring
SAY @35
IF ~~ THEN EXIT
END


IF WEIGHT #0 ~GlobalGT("UBScarRingFetch","LOCALS",0)~ THEN BEGIN RingFetchQuestReturn
  SAY @36
+ ~Dead("SewerOgre") !PartyHasItem("UBSCARIN")~ + @37 EXIT
+ ~Global("UBScarRingFetch","LOCALS",1) PartyHasItem("UBSCARIN")~ + @38 DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 34_UB
+ ~Global("UBScarRingFetch","LOCALS",2) PartyHasItem("UBSCARIN")~ + @38 DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 34
++ @26 DO ~SetGlobal("UBScarRingFetch","LOCALS",0)~ + 33
END

END //APPEND



REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN 34 END
BEGIN 0 END
~TakePartyItem("%tutu_var%RING19")~ ~TakePartyItem("UBSCARIN")~


APPEND %tutu_var%SCAR
IF ~~ THEN BEGIN 34_UB
  SAY @1
  IF ~PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @2 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @3 GOTO NoWay
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @4 GOTO WillReturnBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("UBSCARIN")~ REPLY @5 GOTO NoWay
END

IF ~~ THEN BEGIN AlreadyHaveBody
  SAY @6
  COPY_TRANS %tutu_var%SCAR 34
END

IF ~~ THEN BEGIN NoWay
  SAY @7
  COPY_TRANS %tutu_var%SCAR 33
END

IF ~~ THEN BEGIN WillReturnBody
  SAY @8
  IF ~~ THEN DO ~SetGlobal("ScarBodyFetch","GLOBAL",1)~ EXIT
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",1)~ THEN BEGIN BodyFetchQuestReturn
  SAY @9
  IF ~PartyHasItem("UBFEBODY")~ THEN REPLY @10 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN REPLY @11 GOTO NoBodyYet
  IF ~~ THEN REPLY @12 GOTO NoWay
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",2)
PartyHasItem("UBFEBODY")~ THEN BEGIN ChangedMind
  SAY @13
  IF ~~ THEN REPLY @14 GOTO AlreadyHaveBody
END

IF ~~ THEN BEGIN NoBodyYet
  SAY @15
  IF ~~ THEN EXIT
END
END

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN AlreadyHaveBody END
BEGIN 0 END
~TakePartyItem("%tutu_var%RING19")~ ~TakePartyItem("UBFEBODY") SetGlobal("ScarBodyFetch","GLOBAL",3)~

REPLACE_TRANS_ACTION %tutu_var%SCAR
BEGIN NoWay END
BEGIN 0 END
~GiveGoldForce(1000)
AddexperienceParty(2000)~
~GiveGoldForce(500)
AddexperienceParty(3000)
SetGlobal("ScarBodyFetch","GLOBAL",2)~

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Re: Scar quest extention extention (for v13)
« Reply #3 on: October 06, 2010, 06:58:34 AM »
tp2 additions:
Hm, maybe I should provide a ring.itm instead of the COPY_EXISTING, for people with a minimal install?

COPY_EXISTING ~%tutu_var%RING19.ITM~ ~override/UBSCARIN.ITM~ // Create a unique item for the ring
  SAY NAME1 @113
  SAY NAME2 @113
SAY DESC @114

COPY_EXISTING ~%ESewers%.ARE~ ~override~
 // PATCH_IF SOURCE_SIZE > 0x28f BEGIN
    LAUNCH_PATCH_FUNCTION ADD_AREA_ITEM
      INT_VAR container_to_add_to = 1
      STR_VAR item_to_add = UBSCARIN //custom ring
 //   END
  END
BUT_ONLY_IF_IT_CHANGES

Hurricane

  • Guest
Re: Scar quest extention extention (for v13)
« Reply #4 on: January 24, 2012, 01:38:42 PM »
I've discovered something: Since the Sashenstar's daughter's body UBFEBODY is based on the existing item MISC79, it has the wrong weight in a BGT install. In BG1, MISC79 is a female's body with a correct weight of 130, but in BG2 the item is Raissa's skin (not a body) with a weight of only 13. UB has to manually set the weight of UBFEBODY to 130 for the BGT case. :)

Hurricane

  • Guest
Re: Scar quest extention extention (for v13)
« Reply #5 on: January 24, 2012, 02:03:21 PM »
I shouldn't have wanted to submit my post too quickly. There was more I meant to say.

For one thing, I think the issue about the weight isn't only present in BGT but would apply to Tutu as well.

Secondly, I wanted to add that the patching of the description should be changed. Instead of setting @16 as the identified description, it should be the unidentified description. The identified description is set to None by default and should stay that way (it's the common behavior for non-magical quest items and similar stuff). Also, if UB would set @16 as the identified description, the unidentified description would still pertain to the original MISC79. I know this wouldn't be visible in-game, but it would still be wrong.

Offline hook71

  • Planewalker
  • *****
  • Posts: 61
  • Gender: Male
Re: Scar quest extention extention (for v13)
« Reply #6 on: January 24, 2012, 02:22:13 PM »
In a BGT installation the body should be based on BGMISC79 instead as this is the renamed item from BG1. In BGT 1.13 it also has the correct weight of 130.

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Re: Scar quest extention extention (for v13)
« Reply #7 on: January 24, 2012, 02:30:53 PM »
Thank you both for the report and information! I will correct accordingly.

Offline jastey

  • Planewalker
  • *****
  • Posts: 1241
  • Gender: Female
Re: Scar quest extention extention (for v13)
« Reply #8 on: January 24, 2012, 02:37:10 PM »
Very good catch, indeed! Now the right game-dependent prefix for Tutu, BGT, and BG is used in my local install. The description and weight should be alright then, too. Will be corrected in the next update.

Hurricane

  • Guest
Re: Scar quest extention extention (for v13)
« Reply #9 on: January 24, 2012, 03:35:29 PM »
In BGT 1.13 it also has the correct weight of 130.
I know - I'm the one who corrected it. ;D (scnr)
When I looked at the weight of UBFEBODY, I thought: "That oversight looks awfully familiar..." ;D

 

With Quick-Reply you can write a post when viewing a topic without loading a new page. You can still use bulletin board code and smileys as you would in a normal post.

Warning: this topic has not been posted in for at least 120 days.
Unless you're sure you want to reply, please consider starting a new topic.

Name: Email:
Verification:
Type the letters shown in the picture
Listen to the letters / Request another image
Type the letters shown in the picture:
What color is grass?:
What is the seventh word in this sentence?:
What is five minus two (use the full word)?: