Author Topic: Stupid TP2's  (Read 3047 times)

Offline Mobius572

  • Planewalker
  • *****
  • Posts: 11
  • Gender: Male
  • A God among Men
Stupid TP2's
« on: January 31, 2010, 07:47:59 AM »
How do I write a .tp2? Lots of people say to post the contents of the TP2, so here it is:

BACKUP ~ZakTheNPC\backup~
AUTHOR ~warjack827@yahoo.com~
BEGIN ~Zak the NPC for BG2:Soa/ToB~

// The following is the copying of Zak's .cre file, as well as assigning his sound-set.  See the file sndslot.ids for a listing of sounds you can add.

COPY ~ZakTheNPC\J#Zak.cre~ ~override\J#Zak.cre~
SAY NAME1 ~Zak~
SAY NAME2 ~Zak~
SAY SELECT_COMMON4 ~Blah blah blah.~ [Zak1] // [Zak1] is the name of the .wav
file for this sound
SAY SELECT_COMMON5 ~Give the word.~ [Zak2]
SAY SELECT_COMMON6 ~Point the way.~ [Zak3]
SAY SELECT_ACTION1 ~I'm on the job.~ [Zak4]
SAY SELECT_ACTION2 ~As you wish.~ [Zak5]


// The following is telling WeiDU to compile the following .d files

COMPILE ~ZakTheNPC\J#Zak.d~

// The following is compilling the script and placing it in the override.  We haven't actually made a script yet, though, so this isn't necessary.

COMPILE ~ZakTheNPC\J#Zak.baf~

// The following is appending what we wrote in AR1000.baf to the bottom of
// AR0300.bcs

EXTEND_TOP ~Ar0300.bcs~ ~ZakTheNPC\ar0300.baf~

What do I need to do to my file?
"Death comes swiftly.  FEEL ITS ICY BREATH!"-Sarevok Anchev

Offline Miloch

  • Barbarian
  • Planewalker
  • *****
  • Posts: 1030
  • Gender: Male
Re: Stupid TP2's
« Reply #1 on: February 02, 2010, 04:20:58 AM »
What do you mean, "what do you need to do to it"? Just save it in your ZakTheNPC folder as Setup-ZakTheNPC.tp2, copy WeiDU.exe and rename it Setup-ZakTheNPC.exe in your main game folder, then execute that and hope there's no compile errors (and if it's your first mod, or even your 50th, there will be).

Offline theacefes

  • XTREME METAL ROCKER PUNK CHICK WITH ULTRA SURFBOARD
  • Planewalker
  • *****
  • Posts: 90
  • Gender: Female
  • Is this thing on?
Re: Stupid TP2's
« Reply #2 on: February 09, 2010, 03:42:47 PM »
Quote
SAY SELECT_COMMON4 ~Blah blah blah.~ [Zak1] // [Zak1] is the name of the .wav
file for this sound

This might just be how it pasted in the forum but if this is on two lines in your Tp2, you're going to get an error.
Ace

Offline Mobius572

  • Planewalker
  • *****
  • Posts: 11
  • Gender: Male
  • A God among Men
Re: Stupid TP2's
« Reply #3 on: March 13, 2010, 09:04:43 AM »
Could some one just give me a general outline?  This is frustrating me!

"Death comes swiftly.  FEEL ITS ICY BREATH!"-Sarevok Anchev

Offline berelinde

  • Planewalker
  • *****
  • Posts: 1188
  • Gender: Female
    • Gavin, cleric of Lathander, for Tutu
Re: Stupid TP2's
« Reply #4 on: March 13, 2010, 12:56:40 PM »
One extremely simple untraified mod tp2, coming up.
Code: [Select]
BACKUP ~haldamir/backup~
AUTHOR ~email removed to avoid spambots~

//MODDER

VERSION ~0.5 ALPHA~

README ~haldamir/readme-haldamir.txt~

BEGIN ~Haldamir~

APPEND ~STATE.IDS~
  ~0x80101FEF CD_STATE_NOTVALID~
  UNLESS ~CD_STATE_NOTVALID~

COPY ~haldamir/audio/blank.mus~ ~music~
COPY_EXISTING ~songlist.2da~ ~override~
SET_2DA_ENTRY 0 2 3 ~BLANK.MUS~

ACTION_IF ("%WEIDU_ARCH%" STRING_COMPARE_CASE "x86" = 0) THEN BEGIN // if Windows

  AT_NOW                   ~haldamir/audio-install.bat~   // install...
  AT_INTERACTIVE_UNINSTALL ~haldamir/audio-uninstall.bat~ // ... and uninstall

END ELSE BEGIN // linux or OS X

  AT_NOW                   ~sh haldamir/audio-install.sh~   // install...
  AT_INTERACTIVE_UNINSTALL ~sh haldamir/audio-uninstall.sh~ // ... and uninstall

END


ACTION_IF NOT FILE_EXISTS_IN_GAME ~cdbehbla.pro~ //makes sure the fixpack isn't already installed

THEN BEGIN

ACTION_IF FILE_EXISTS_IN_GAME ~saradush.mve~ THEN BEGIN
  COPY_EXISTING ~interdia.2da~ ~override~
    SET_2DA_ENTRY 17 1 2 ~BIMOEN2~ // fixes ToB version
    BUT_ONLY_IF_IT_CHANGES
END ELSE BEGIN
  APPEND ~interdia.2da~ ~IMOEN       BIMOEN2~ // fixes SoA version
    UNLESS ~BIMOEN2~
END
END

ACTION_IF NOT FILE_EXISTS_IN_GAME ~bimoen2.dlg~ THEN BEGIN
  COMPILE ~haldamir/lib/b!bimoen2.d~
END

INCLUDE ~haldamir/lib/b!ids.tph~
INCLUDE ~haldamir/lib/b!times.tph~

/* creature copying and naming */
COPY ~haldamir/character/b!haldal.bmp~ ~override~
COPY ~haldamir/character/b!haldam.bmp~ ~override~
COPY ~haldamir/character/b!haldas.bmp~ ~override~
COPY ~haldamir/character/b!hal.cre~ ~override~
  ADD_CRE_ITEM ~leat04~ #0 #0 #0 ~IDENTIFIED~ ~ARMOR~
  ADD_CRE_ITEM ~sw1h01~ #0 #0 #0 ~IDENTIFIED~ ~SHIELD~
  ADD_CRE_ITEM ~sw1h02~ #0 #0 #0 ~IDENTIFIED~ ~WEAPON1~ EQUIP
  ADD_CRE_ITEM ~potn52~ #0 #0 #0 ~IDENTIFIED~ ~QITEM1~
  ADD_CRE_ITEM ~bow01~ #0 #0 #0 ~IDENTIFIED~ ~INV1~
  ADD_CRE_ITEM ~arow01~ #14 #0 #0 ~IDENTIFIED~ ~QUIVER1~
  ADD_CRE_ITEM ~arow02~ #5 #0 #0 ~IDENTIFIED~ ~QUIVER2~
  SAY NAME1 ~Haldamir~
  SAY NAME2 ~Haldamir~
  WRITE_ASCII 0x248 ~B!HALS~ #8 // assign override script
  WRITE_ASCII 0x2cc ~B!HAL~ #8 // assign pre-joining dialogue file
  WRITE_ASCII 0x280 ~B!HALDAMIR~ #32 // assign DV
  WRITE_ASCII 0x34  ~b!haldas~ #8     // assign small portrait
  WRITE_ASCII 0x3c  ~b!haldam~ #8     // assign medium portrait
  SAY INITIAL_MEETING ~What are you looking at?~ [bhal01]
  SAY MORALE ~There is no valor here, only death!~ [bhal02]
  SAY HAPPY ~I could have done worse than joining forces with you.~ [bhal03]
  SAY UNHAPPY_ANNOYED ~If only I were back in Cormanthor.~ [bhal04]
  SAY UNHAPPY_SERIOUS ~Seldarine forbid that my presence in a group such as this would ever become known in my homeland. This is no way to behave.~ [bhal05]
  SAY UNHAPPY_BREAKING ~I can stand no more. I would walk every one of the thousands of miles to my homeland barefoot rather than spend another day in this company. Good riddance.~ [bhal06]
  SAY LEADER ~You put much faith in one who has nothing to lose.~ [bhal07]
  SAY TIRED ~I never would have thought there could be so many hours in a day. Let us rest.~ [bhal08]
  SAY BORED ~What freakish test of endurance is this, to stay so long without moving?~ [bhal09]
  SAY BATTLE_CRY1 ~Die!~ [bhal10]
  SAY BATTLE_CRY2 ~Feel my wrath!~ [bhal11]
  SAY BATTLE_CRY3 ~Seldarine, but I'll make you bleed!~ [bhal12]
  SAY BATTLE_CRY4 ~Strike true!~ [bhal13]
  SAY DAMAGE ~Oof.~ [bhal14]
  SAY DYING ~Alas, that I should fall so far from my homeland!~ [bhal16]
  SAY HURT ~Some aid, please! I do not want to die in these barbaric lands!~ [bhal16]
  SAY AREA_FOREST ~Here, I could almost imagine that I was home.~ [bhal17]
  SAY AREA_CITY ~Bah. What foul, steaming dungheaps human cities are.~ [bhal18]
  SAY AREA_DUNGEON ~The air in this place... can you feel it?~ [bhal19]
  SAY AREA_DAY ~The heart always rises in the light of day, even though the light leaves us more exposed.~ [bhal20]
  SAY AREA_NIGHT ~Moonlight and starlight were ever my friends.~ [bhal21]
  SAY SELECT_COMMON1 ~What?~ [bhal22]
  SAY SELECT_COMMON2 ~You want something?~ [bhal23]
  SAY SELECT_COMMON3 ~Your desire?~ [bhal24]
  SAY SELECT_COMMON4 ~Must I?~ [bhal25]
  SAY SELECT_COMMON5 ~Hmm?~ [bhal26]
  SAY SELECT_COMMON6 ~Yes?~ [bhal27]
  SAY SELECT_ACTION1 ~I hear you.~ [bhal28]
  SAY SELECT_ACTION2 ~As you wish.~ [bhal29]
  SAY SELECT_ACTION3 ~All right.~ [bhal30]
  SAY SELECT_ACTION4 ~If I must.~ [bhal31]
  SAY SELECT_ACTION5 ~Hmf.~ [bhal32]
  SAY SELECT_ACTION6 ~As you bid.~ [bhal33]
  SAY SELECT_ACTION7 ~If you think it wise.~ [bhal34]
  SAY SELECT_RARE1 ~Always "right now" with you, isn't it?~ [bhal35]
  SAY SELECT_RARE2 ~I hear and obey, despite my better judgment.~ [bhal36]
  SAY CRITICAL_HIT ~Shrug that one off!~ [bhal37]
  SAY CRITICAL_MISS ~Aargh! You shall not evade my next blow so easily!~ [bhal38]
  SAY TARGET_IMMUNE ~This isn't working! I need a different weapon.~ [bhal39]
  SAY INVENTORY_FULL ~An elven warrior relies on speed as much as endurance. Carry your burdens yourself.~ [bhal40]
  SAY BIO ~When asked about his past, Haldamir smiles, as if greeting an old friend. He was raised in Cormanthor, and spent his life defending it, right up until a wild surge teleported him to Athkatla. He speaks with fond remembrance of his homeland, though without great detail.~
 
/* dialogue compilation */ 
COMPILE ~haldamir/dialogue/b!hal.d~
COMPILE ~haldamir/dialogue/b!halj.d~
COMPILE ~haldamir/dialogue/b!halp.d~
COMPILE ~haldamir/dialogue/bb!hal.d~

ACTION_IF FILE_EXISTS_IN_GAME ~bp#kiv.dlg~ THEN BEGIN
  COMPILE ~haldamir/dialogue/b!kivanbanter.d~
END

/* script compilation */
COMPILE ~haldamir/script/b!hals.baf~
COMPILE ~haldamir/script/b!hald.baf~
EXTEND_TOP ~AR0700.bcs~ ~haldamir/script/b!ar0700.baf~

/* 2da appending */
//2da appending for dialogues
APPEND ~interdia.2da~ ~b!haldamir    bb!hal       bb!hal25~
UNLESS ~b!haldamir~

APPEND ~pdialog.2da~ ~b!haldamir        b!halp             b!halj            b!hald             b!hal25p             b!hal25j             b!hal25d       b!hal25s~
UNLESS ~b!haldamir~

Offline Mobius572

  • Planewalker
  • *****
  • Posts: 11
  • Gender: Male
  • A God among Men
Re: Stupid TP2's
« Reply #5 on: November 22, 2010, 04:15:42 PM »
It worked!!!

Thx so much.  I know I'm not the only person who needs help with this, so...

THX!  :D
"Death comes swiftly.  FEEL ITS ICY BREATH!"-Sarevok Anchev

 

With Quick-Reply you can write a post when viewing a topic without loading a new page. You can still use bulletin board code and smileys as you would in a normal post.

Warning: this topic has not been posted in for at least 120 days.
Unless you're sure you want to reply, please consider starting a new topic.

Name: Email:
Verification:
Type the letters shown in the picture
Listen to the letters / Request another image
Type the letters shown in the picture:
What color is grass?:
What is the seventh word in this sentence?:
What is five minus two (use the full word)?: