Author Topic: Scar and the Sashenstars' daughter  (Read 10814 times)

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Scar and the Sashenstars' daughter
« on: February 18, 2006, 05:50:54 PM »
MISC79: Female Body--it obviously wouldn't hurt to change 1/3rd to 1/2 of the bodies found in the BG sewers to be Female, with the most obvious contender being the one found in the same web-cocoon as the Ruby Ring. Arkion would need be tweaked, to accept a Female Body as well as a Male one, and perhaps Scar should only offer his "Ruby Ring" reward if you also go back and bring him a Female Body to give to the Sashenstars.

OK, I've completed this, sort of.  I replaced three male bodies with females, including the container with the ruby ring.  I've also altered Arkion's dialog to accept a male or female body.

I didn't, however, change Scar's dialog to expect the female body.  I would think that, to do that, the body in that particular cocoon would need a specific item code.  I could either not change any of the other bodies *except* for the one with the ruby ring, or make a new item for the Sashenstar's daughter.  Otherwise any random female body would be accepted by Scar.

I can do what you suggest, it'd just take some extra coding.  Does anyone think it'd really be worth it, though?  Would the Sashenstars want a mangled corpse to give a proper burial, or would they be disgusted?
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline SixOfSpades

  • Planewalker
  • *****
  • Posts: 821
  • Gender: Male
    • Volothamp's Comeuppance
Scar and the Sashenstars' daughter
« Reply #1 on: February 27, 2006, 03:20:14 PM »
I didn't, however, change Scar's dialog to expect the female body.  I would think that, to do that, the body in that particular cocoon would need a specific item code.  I could either not change any of the other bodies *except* for the one with the ruby ring, or make a new item for the Sashenstar's daughter.  Otherwise any random female body would be accepted by Scar.

I can do what you suggest, it'd just take some extra coding.  Does anyone think it'd really be worth it, though?  Would the Sashenstars want a mangled corpse to give a proper burial, or would they be disgusted?
Personally, if I were the Sashenstars I would want something to bury, especially since I can just pay somebody else to actually touch the corpse tp prepare it for burial and put it in the coffin. Closed-casket funeral, with lots of incense.

I would keep Scar's dialog mostly the way it is: The bonus that he offers if you brought him the ring should not be anywhere near its current amount (2000 gold?), it should be a lot closer to the actual market value of a Ruby Ring. After you bring him the news about the Ogre-Mage, then he can ask you to go retrieve the body (which you can elect not to do), and give you the large reward if you successfully bring back the correct corpse.

Perhaps the "all the Female Bodies look the same" problem should be simplified by having only one Female Body in the sewers, in the web-sack with the Ruby Ring. Alternatively, it'd be easy enough to just create a duplicate item.

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Scar and the Sashenstars' daughter
« Reply #2 on: March 03, 2006, 09:53:46 PM »
OK.  I'll need to play around with Scar's dialog a bit, but I'll try to add this in.
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Re: Scar and the Sashenstars' daughter
« Reply #3 on: March 25, 2006, 01:07:22 PM »
OK, I've overhauled this a bit.  New code is below.  Please feel free to criticize the dialogue.

Code: [Select]
BEGIN ~Scar and the Sashenstar's Daughter~

COMPILE ~bg1ub/Scar/ubscar.d~

COPY_EXISTING MISC79.ITM ~OVERRIDE/UBFEBODY.ITM~ // Create a unique item for the Sashenstar's daughter

COPY_EXISTING AR0224.ARE OVERRIDE // Sewers
WRITE_ASCII 0x28c0 ~MISC79~       // Replace Male Body with Female Body in Container 1
BUT_ONLY_IF_IT_CHANGES

COPY_EXISTING AR0226.ARE OVERRIDE // Sewers
WRITE_ASCII 0x239c ~UBFEBODY~     // Replace Male Body with the Sashenstar's daughter in Container 1 (with ruby ring)
WRITE_ASCII 0x2450 ~MISC79~       // Replace Male Body with Female Body in Container 4
BUT_ONLY_IF_IT_CHANGES
Quote
REPLACE ARKION
IF WEIGHT #1 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("MISC79")
~ THEN BEGIN 3 // from:
  SAY ~Ah, a ripe one. Ya've done well, there haven't ya. Here's 250 gp to relieve the stink of it all... Ah, Nemphre, I'll have that ring yet!~ /* #15015 */
  IF ~PartyHasItem("MISC80")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

APPEND ARKION
IF WEIGHT #-1 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("MISC80")
~ THEN BEGIN EitherBody
  SAY ~Ah, a ripe one. Ya've done well, there haven't ya. Here's 250 gp to relieve the stink of it all... Ah, Nemphre, I'll have that ring yet!~ /* #15015 */
  IF ~PartyHasItem("MISC80")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

REPLACE SCAR
IF ~~ THEN BEGIN 34
  SAY ~I recognize this ring.  This belonged to the Sashenstar's daughter; she was among the missing, as well.  I am certain that the family will want to have a proper burial for their daughter.  Would you be willing to return to the sewers and retrieve the body.  You may return it to me and I will break the news to the Sashenstars.~
  IF ~PartyHasItem("MISC79")~ THEN REPLY ~Actually, I have brought the body with me.  She was dressed so exquisitely that I felt she must be someone important.~ GOTO AlreadyHaveBody
  IF ~!PartyHasItem("MISC79")~ THEN REPLY ~There's no way I'm returning to those fetid sewers.  I'm sure you have a spare man that you can send down there to fetch the body.~ GOTO NoWay
  IF ~!PartyHasItem("MISC79")~ THEN REPLY ~If it will help to becalm a grieving family, I will do whatever I can.  I shall return the body to you.~ GOTO WillReturnBody
  IF ~!PartyHasItem("MISC79")~ THEN REPLY ~I have better things to do than these petty "fetch" quests.  Get the body yourself.~ GOTO NoWay
END
END

APPEND SCAR
IF ~~ THEN BEGIN AlreadyHaveBody
  SAY ~You have done well, and perhaps now the Sashenstars will find some peace.  Please accept this 3,000 gold bonus for the return of the body.  Anyway, I'm going to need some people to do some investigating of the Iron Throne.  I'm just going to finish up some paper work, then I'll be just outside the main doors of the Flaming Fist compound.  If you wish to discuss the Iron Throne, just come talk to me there.~
  IF ~~ THEN DO ~TakePartyItem("RING19")
TakePartyItem("MISC79")
GiveGoldForce(3000)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",3)
EscapeArea()
~ JOURNAL #10649 /* ~Scar is waiting outside of the Flaming Fist barracks.  He wants to discuss the suspicions he has about the Iron Throne.~ */ EXIT
END

IF ~~ THEN BEGIN NoWay
  SAY ~You disappoint me, but I thank you for ridding the sewers of the scourge and returning the ring.  Please accept this 500 gold bonus for the return of the ring.  Anyway, I'm going to need some people to do some investigating of the Iron Throne.  I'm just going to finish up some paper work, then I'll be just outside the main doors of the Flaming Fist compound.  If you wish to discuss the Iron Throne, just come talk to me there.~
  IF ~~ THEN DO ~TakePartyItem("RING19")
GiveGoldForce(500)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",2)
EscapeArea()
~ JOURNAL #10649 /* ~Scar is waiting outside of the Flaming Fist barracks.  He wants to discuss the suspicions he has about the Iron Throne.~ */ EXIT
END

IF ~~ THEN BEGIN WillReturnBody
  SAY ~You are a valiant person indeed.  I will await your return.~
  IF ~~ THEN DO ~SetGlobal("ScarBodyFetch","GLOBAL",1)~ EXIT
END

IF WEIGHT #-1 ~Global("ScarBodyFetch","GLOBAL",1)~ THEN BEGIN BodyFetchQuestReturn
  SAY ~Ah, you have returned.  Have you brought the body of the Sashenstar's daughter?~
  IF ~PartyHasItem("MISC79")~ THEN REPLY ~Yes, actually.  Here you go.~ GOTO AlreadyHaveBody
  IF ~!PartyHasItem("MISC79")~ THEN REPLY ~No, not yet.~ GOTO NoBodyYet
  IF ~~ THEN REPLY ~I've changed my mind, Scar.  Get the body yourself.~ GOTO NoWay
END

IF WEIGHT #-2 ~Global("ScarBodyFetch","GLOBAL",2)
PartyHasItem("MISC79")~ THEN BEGIN ChangedMind
  SAY ~I see that you have brought the body of the Sashenstar's daughter with you.  Had a change of heart, perhaps?~
  IF ~~ THEN REPLY ~Something like that.  I'd appreciate it if you would take this body off of my hands now, thanks.~ GOTO AlreadyHaveBody
END

IF ~~ THEN BEGIN NoBodyYet
  SAY ~I see.  I am a busy man, so please don't return until you have the body with you.~
  IF ~~ THEN EXIT
END
END
<Moongaze> Luckily BWL has a very understanding and friendly admin.

 

With Quick-Reply you can write a post when viewing a topic without loading a new page. You can still use bulletin board code and smileys as you would in a normal post.

Warning: this topic has not been posted in for at least 120 days.
Unless you're sure you want to reply, please consider starting a new topic.

Name: Email:
Verification:
Type the letters shown in the picture
Listen to the letters / Request another image
Type the letters shown in the picture:
What color is grass?:
What is the seventh word in this sentence?:
What is five minus two (use the full word)?: