Author Topic: "Mysterious Vial"  (Read 12281 times)

Offline SimDing0™

  • Back In Black
  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3496
  • Gender: Male
  • Word Enhancer
"Mysterious Vial"
« on: August 22, 2005, 07:08:06 AM »
Quote
***1) No one is interested in the "Vials of mysterious fluid" you get from the Nashkel mines. You'd think that at least Thalantyr or the fellow at the Sorcerous Sunderies would be interested in it's alchemey.***

I kept thinking I wasn't doing something right when I went to the mayor.  "We explored the mines and found out that you were being sabotaged!  An evil cleric was in the bowels of the mine, along with a horde of kobolds.  They were poisoning the ore, and THIS is what they were doing it with!"

Everytime I talked to him I would check my inventory and see that the vials were still there.  Having seen on other occasions that items could be extracted from my inventory by the game, I finally decided it was a bug, and just dropped them as if he had taken them.

It would make sense to me that they would serve as proof that you had not only been in the mines but actually found the problem, and hadn't simply been drinking in a tavern for the past week before asking for reward money.  At the least, they should help serve as a base for someone to find an "antidote" to this "poison".

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
"Mysterious Vial"
« Reply #1 on: February 06, 2006, 11:22:40 PM »
This is one of the main things that has bugged me about the original game.  You find several of these bottles, but no one anywhere gives a fuck about them.  Not even half-fucks, quarter-fucks, missionaries, doggy-styles, reverse cowgirls, or Italian chandeliers.

The easiest way I can think to do something about this is to have the mayor of Nashkel say "oh, looky, this is the culprit.  I'll take it off your hands." 

A Cromwellian approach would be for Taerumorwhateverhisnameis to take the vial and combine it with... something... to make... something else.  Or Thalantyr, only to make a magical item.

But these scenarios might be too cliché.  Any ideas from the audience? 
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline SimDing0™

  • Back In Black
  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3496
  • Gender: Male
  • Word Enhancer
Re: "Mysterious Vial"
« Reply #2 on: February 07, 2006, 03:57:10 AM »
I have a partially written quest for this.

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Re: "Mysterious Vial"
« Reply #3 on: February 07, 2006, 12:07:38 PM »
Oh.  Well, nifty, then.  :)
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline SimDing0™

  • Back In Black
  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3496
  • Gender: Male
  • Word Enhancer
Re: "Mysterious Vial"
« Reply #4 on: February 20, 2006, 02:54:02 PM »
Code: [Select]
APPEND BERRUN

IF WEIGHT #-1 ~PartyHasItem("MISC85")~ THEN BEGIN Success0a
  SAY ~You have returned!  It would seem I was right to trust you. What can you tell of the events that took place in the mines?~
  IF ~~ THEN REPLY ~I'd sooner not share the tricks of the trade, if it's all the same to you.~ GOTO Success2
  IF ~~ THEN REPLY ~There isn't much to tell really. Some kobolds found their way into the mines and wreaked havoc. You needn't worry about them any more though.~ GOTO Success3
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!HasItem("potn48")
!HasItem("misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore somehow, but he is dead now.~ GOTO Success4
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
HasItem("potn48")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of it here.~ GOTO Success5
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!HasItem("potn48")
HasItem("misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of the corrupted ore here.~ GOTO Success6
  IF ~GlobalGT("D0TaintedOreQuest","GLOBAL",0)~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I am investigating the problem.~ GOTO Success7
END

IF WEIGHT #-1 ~PartyHasItem("SCRL2W")~ THEN BEGIN Success0b
  SAY ~You have returned!  It would seem I was right to trust you. What can you tell of the events that took place in the mines?~
  IF ~~ THEN REPLY ~I'd sooner not share the tricks of the trade, if it's all the same to you.~ GOTO Success2
  IF ~~ THEN REPLY ~There isn't much to tell really. Some kobolds found their way into the mines and wreaked havoc. You needn't worry about them any more though.~ GOTO Success3
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!HasItem("potn48")
!HasItem("misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore somehow, but he is dead now.~ GOTO Success4
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
HasItem("potn48")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of it here.~ GOTO Success5
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!HasItem("potn48")
HasItem("misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of the corrupted ore here.~ GOTO Success6
  IF ~GlobalGT("D0TaintedOreQuest","GLOBAL",0)~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I am investigating the problem.~ GOTO Success7
END

IF ~~ THEN BEGIN Success2
  SAY ~As you wish. The town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success3
  SAY ~I see. Curious how such an organised band could emerge without notice. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success4
  SAY ~I wonder what his motive could have been, and how he was able to taint the iron so effectively. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success5
SAY ~What is this you say? You were wise in bringing back a sample. I fear that distrust of magic means we are ill-equipped to analyse the poison, however. Our isolation compounds the problem. It would be quicker to take the vial north to Thalantyr of Beregost than to journey south in search of an Amnish archmage.~
= ~If you have any of the tainted ore you might consider taking it to Taerom Fuiruim while you are there. I don't doubt his ability to devise some way to work around its brittle properties.~
= ~Best if you not mention this to anyone, however. Relations between Baldur's Gate and Amn are tense, to say the least, and I should perhaps not be sending something so valuable out of Amnish hands.~
= ~Regardless, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",1)
ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success6
SAY ~What is this you say? You were wise in bringing back a sample. You might consider taking it to Taerom Fuiruim in Beregost. I don't doubt his ability to devise some way to work around its brittle properties, and he is much closer than any such renowned Amnish smithy.~
= ~Best if you not mention this to anyone, however. Relations between Baldur's Gate and Amn are tense, to say the least, and I should perhaps not be sending something so valuable out of Amnish hands.~
= ~Regardless, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success7
  SAY ~Glad to hear it. I wonder what his motive could have been. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("MISC85")
TakePartyItem("SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

END


EXTEND_BOTTOM TAEROM 0 4 6 12
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
HasItem("misc87")~ THEN REPLY ~Never mind about that just now. I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ GOTO Tainted
END

EXTEND_TOP TAEROM 14 #1
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
HasItem("misc87")~ THEN REPLY ~I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ GOTO Tainted
END

REPLACE TAEROM
IF WEIGHT #3 /* Triggers after states #: 13 even though they appear after this state */
~!GlobalTimerExpired("Taerom2","GLOBAL")
Global("MakeArmor","GLOBAL",1)
~ THEN BEGIN 8 // from:
  SAY #187 /* ~It's not ready as yet.  Perhaps another day or two.  Be patient; quality takes time.~ */
  IF ~~ THEN REPLY #15267 /* ~Could you show us what you have for sale?~ */ DO ~StartStore("Taerum",LastTalkedToBy())~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ EXIT
  IF ~~ THEN REPLY ~I look forward to seeing the result.~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ EXIT
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
HasItem("misc87")~ THEN REPLY ~Never mind about that just now. I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ GOTO Tainted
END
END

APPEND TAEROM
IF ~~ THEN BEGIN Tainted
SAY ~Pass it here. Hmm. Strange indeed. The iron has certainly been tainted with some compound. I don't suppose you have any clue what that might have been?~
  IF ~HasItem("potn48")~ THEN REPLY ~As a matter of fact, yes. I have this vial here which I found in the same mine as the ore.~ GOTO Tainted2
  IF ~~ THEN REPLY ~No, but I could try to find out if that would help.~ GOTO Tainted3
  IF ~~ THEN REPLY ~Unfortunately not. Is there nothing you can do with the ore alone?~ GOTO Tainted3
END

IF ~~ THEN BEGIN Tainted2
SAY ~Ah, excellent. But it is beyond my abilities to examine this. Take it to Thalantyr; he should have no trouble in discerning its properties. In the meantime, I will see what I can do to counteract the properties of this ore. I should be able to reduce the effects of the compound.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",3)~ THEN REPLY ~I have already taken a sample to Thalantyr, and he agreed to examine it.~ GOTO Tainted4
  IF ~!Global("D0TaintedOreQuest","GLOBAL",3)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",2)
AddexperienceParty(750)
TakePartyItem("misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END

IF ~~ THEN BEGIN Tainted3
SAY ~There is only so much I can do. If you are able to find a sample of the poison, take it to Thalantyr; he should have no trouble in discerning its properties. In the meantime, I will see what I can do to counteract the properties of this ore. I should be able to reduce the effects of the compound.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",3)~ THEN REPLY ~I have already taken a sample to Thalantyr, and he agreed to examine it.~ GOTO Tainted4
  IF ~!Global("D0TaintedOreQuest","GLOBAL",3)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",2)
AddexperienceParty(750)
TakePartyItem("misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END

IF ~~ THEN BEGIN Tainted4
  SAY ~Then I will contact him and discover what he has found. You have my thanks for bringing this to my attention.~
  IF ~~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",4)
AddexperienceParty(750)
TakePartyItem("misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END
END


EXTEND_BOTTOM THALAN 1
  IF ~Global("D0TaintedOreQuest","GLOBAL",1)
HasItem("potn48")~ THEN REPLY ~Berrun Ghastkill suggested you might be interested in examining this vial. It is a poison that was used to taint ore from the Nashkell mines, causing problems with the iron along the Sword Coast.~ GOTO Examine
  IF ~Global("D0TaintedOreQuest","GLOBAL",2)
HasItem("potn48")~ THEN REPLY ~Taerom Fuiruim suggested you might be interested in examining this vial. It is a poison that was used to taint ore from the Nashkell mines, causing problems with the iron along the Sword Coast.~ GOTO Examine
END

APPEND THALAN
IF ~~ THEN BEGIN Examine
  SAY ~A remarkable compound. It must have taken a skilled alchemist to concoct this. I may be able to formulate an antidote to salvage some of the current iron stocks, although I doubt it will be sufficient to resolve the crisis. Leave it with me, and I will contact Taerom if I have any success.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",2)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",4)
AddexperienceParty(750)
TakePartyItem("potn48")~ JOURNAL ~I showed a vial of mineral poison from the Nashkel mines to Thalantyr. He agreed to examine it and try to create an antidote. Hopefully this will have some effect on the iron crisis, although we cannot hope for much.~ EXIT
END
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",3)
AddexperienceParty(750)
TakePartyItem("potn48")~ JOURNAL ~I showed a vial of mineral poison from the Nashkel mines to Thalantyr. He agreed to examine it and try to create an antidote. Hopefully this will have some effect on the iron crisis, although we cannot hope for much.~ EXIT
END
END

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Re: "Mysterious Vial"
« Reply #5 on: February 20, 2006, 05:01:46 PM »
Is this the complete quest?  If so, rock on!
Will add it when I get home.  :)
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Re: "Mysterious Vial"
« Reply #6 on: February 20, 2006, 07:46:03 PM »
OK, had a chance to actually read it.  It all sounds very good.

I did have one question, though.  After giving the vial to Thalantyr, is there any kind of follow-up?  Granted, it's fine as it is, as at least you can now get rid of the crap from the mine. 
<Moongaze> Luckily BWL has a very understanding and friendly admin.

Offline SimDing0™

  • Back In Black
  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3496
  • Gender: Male
  • Word Enhancer
Re: "Mysterious Vial"
« Reply #7 on: February 21, 2006, 02:39:40 AM »
The intention was that it'll have a percentage reduction on the chance of weapons breaking, but that'll only work in Tutu.

Offline icelus

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3173
  • Gender: Male
Re: "Mysterious Vial"
« Reply #8 on: April 16, 2006, 01:47:56 PM »
Sim, I've made the changes to the filename references for Tutu.  Are there any other changes you'd like to make to this quest?

Quote
APPEND _BERRUN

IF WEIGHT #-1 ~PartyHasItem("_MISC85")~ THEN BEGIN Success0a
  SAY ~You have returned!  It would seem I was right to trust you. What can you tell of the events that took place in the mines?~
  IF ~~ THEN REPLY ~I'd sooner not share the tricks of the trade, if it's all the same to you.~ GOTO Success2
  IF ~~ THEN REPLY ~There isn't much to tell really. Some kobolds found their way into the mines and wreaked havoc. You needn't worry about them any more though.~ GOTO Success3
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!PartyHasItem("_potn48")
!PartyHasItem("_misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore somehow, but he is dead now.~ GOTO Success4
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
PartyHasItem("_potn48")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of it here.~ GOTO Success5
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!PartyHasItem("_potn48")
PartyHasItem("_misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of the corrupted ore here.~ GOTO Success6
  IF ~GlobalGT("D0TaintedOreQuest","GLOBAL",0)~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I am investigating the problem.~ GOTO Success7
END

IF WEIGHT #-1 ~PartyHasItem("_SCRL2W")~ THEN BEGIN Success0b
  SAY ~You have returned!  It would seem I was right to trust you. What can you tell of the events that took place in the mines?~
  IF ~~ THEN REPLY ~I'd sooner not share the tricks of the trade, if it's all the same to you.~ GOTO Success2
  IF ~~ THEN REPLY ~There isn't much to tell really. Some kobolds found their way into the mines and wreaked havoc. You needn't worry about them any more though.~ GOTO Success3
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!PartyHasItem("_potn48")
!PartyHasItem("_misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore somehow, but he is dead now.~ GOTO Success4
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
PartyHasItem("_potn48")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of it here.~ GOTO Success5
  IF ~Global("D0TaintedOreQuest","GLOBAL",0)
!PartyHasItem("_potn48")
PartyHasItem("_misc87")~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I have a sample of the corrupted ore here.~ GOTO Success6
  IF ~GlobalGT("D0TaintedOreQuest","GLOBAL",0)~ THEN REPLY ~A half-orc named Mulahey was corrupting the iron ore with a mineral poison. I am investigating the problem.~ GOTO Success7
END

IF ~~ THEN BEGIN Success2
  SAY ~As you wish. The town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success3
  SAY ~I see. Curious how such an organised band could emerge without notice. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success4
  SAY ~I wonder what his motive could have been, and how he was able to taint the iron so effectively. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success5
SAY ~What is this you say? You were wise in bringing back a sample. I fear that distrust of magic means we are ill-equipped to analyse the poison, however. Our isolation compounds the problem. It would be quicker to take the vial north to Thalantyr of Beregost than to journey south in search of an Amnish archmage.~
= ~If you have any of the tainted ore you might consider taking it to Taerom Fuiruim while you are there. I don't doubt his ability to devise some way to work around its brittle properties.~
= ~Best if you not mention this to anyone, however. Relations between Baldur's Gate and Amn are tense, to say the least, and I should perhaps not be sending something so valuable out of Amnish hands.~
= ~Regardless, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",1)
ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success6
SAY ~What is this you say? You were wise in bringing back a sample. You might consider taking it to Taerom Fuiruim in Beregost. I don't doubt his ability to devise some way to work around its brittle properties, and he is much closer than any such renowned Amnish smithy.~
= ~Best if you not mention this to anyone, however. Relations between Baldur's Gate and Amn are tense, to say the least, and I should perhaps not be sending something so valuable out of Amnish hands.~
= ~Regardless, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

IF ~~ THEN BEGIN Success7
  SAY ~Glad to hear it. I wonder what his motive could have been. Still, the town thanks you wholeheartedly, and is pleased to give you the proper reward. Please take this 900 gold for your efforts. It is a small fortune by anyone's standards. Thank you again.~
  IF ~~ THEN DO ~ReputationInc(1)
GivePartyGold(900)
AddexperienceParty(1000)
TakePartyItem("_MISC85")
TakePartyItem("_SCRL2W")
EscapeArea()~ JOURNAL #19438 /* ~I successfully cleared the Nashkel mines, and was rewarded handsomely for my efforts. 900 gold from Berrun Ghastkill, and the thanks of the entire town. Iron will slowly filter back to the coast now, though transporting it is still a treacherous business. The bandits on the roads will have to be dealt with.~ */ EXIT
END

END


EXTEND_BOTTOM _TAEROM 0 4 6 12
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
PartyHasItem("_misc87")~ THEN REPLY ~Never mind about that just now. I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ GOTO Tainted
END

EXTEND_TOP _TAEROM 14 #1
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
PartyHasItem("_misc87")~ THEN REPLY ~I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ GOTO Tainted
END

REPLACE _TAEROM
IF WEIGHT #3 /* Triggers after states #: 13 even though they appear after this state */
~!GlobalTimerExpired("Taerom2","GLOBAL")
Global("MakeArmor","GLOBAL",1)
~ THEN BEGIN 8 // from:
  SAY #187 /* ~It's not ready as yet.  Perhaps another day or two.  Be patient; quality takes time.~ */
  IF ~~ THEN REPLY #15267 /* ~Could you show us what you have for sale?~ */ DO ~StartStore("_taerum",LastTalkedToBy())~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ EXIT
  IF ~~ THEN REPLY ~I look forward to seeing the result.~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ EXIT
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)
!Global("D0TaintedOreQuest","GLOBAL",4)
PartyHasItem("_misc87")~ THEN REPLY ~Never mind about that just now. I have this piece of iron ore, which I believe is tainted. It is the cause of the iron crisis along the Sword Coast.~ JOURNAL #5837 /* ~Taerom is making a suit of plate mail out of my ankheg shell.  It will be ready within a tenday.~ */ GOTO Tainted
END
END

APPEND _TAEROM
IF ~~ THEN BEGIN Tainted
SAY ~Pass it here. Hmm. Strange indeed. The iron has certainly been tainted with some compound. I don't suppose you have any clue what that might have been?~
  IF ~PartyHasItem("_potn48")~ THEN REPLY ~As a matter of fact, yes. I have this vial here which I found in the same mine as the ore.~ GOTO Tainted2
  IF ~~ THEN REPLY ~No, but I could try to find out if that would help.~ GOTO Tainted3
  IF ~~ THEN REPLY ~Unfortunately not. Is there nothing you can do with the ore alone?~ GOTO Tainted3
END

IF ~~ THEN BEGIN Tainted2
SAY ~Ah, excellent. But it is beyond my abilities to examine this. Take it to Thalantyr; he should have no trouble in discerning its properties. In the meantime, I will see what I can do to counteract the properties of this ore. I should be able to reduce the effects of the compound.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",3)~ THEN REPLY ~I have already taken a sample to Thalantyr, and he agreed to examine it.~ GOTO Tainted4
  IF ~!Global("D0TaintedOreQuest","GLOBAL",3)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",2)
AddexperienceParty(750)
TakePartyItem("_misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END

IF ~~ THEN BEGIN Tainted3
SAY ~There is only so much I can do. If you are able to find a sample of the poison, take it to Thalantyr; he should have no trouble in discerning its properties. In the meantime, I will see what I can do to counteract the properties of this ore. I should be able to reduce the effects of the compound.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",3)~ THEN REPLY ~I have already taken a sample to Thalantyr, and he agreed to examine it.~ GOTO Tainted4
  IF ~!Global("D0TaintedOreQuest","GLOBAL",3)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",2)
AddexperienceParty(750)
TakePartyItem("_misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END

IF ~~ THEN BEGIN Tainted4
  SAY ~Then I will contact him and discover what he has found. You have my thanks for bringing this to my attention.~
  IF ~~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",4)
AddexperienceParty(750)
TakePartyItem("_misc87")~ JOURNAL ~Taerom Fuiruim is examining the tainted ore I recovered from the Nashkel mines. He believes he should now be able to produce less brittle iron as a result.~ EXIT
END
END


EXTEND_BOTTOM _THALAN 1
  IF ~Global("D0TaintedOreQuest","GLOBAL",1)
PartyHasItem("_potn48")~ THEN REPLY ~Berrun Ghastkill suggested you might be interested in examining this vial. It is a poison that was used to taint ore from the Nashkell mines, causing problems with the iron along the Sword Coast.~ GOTO Examine
  IF ~Global("D0TaintedOreQuest","GLOBAL",2)
PartyHasItem("_potn48")~ THEN REPLY ~Taerom Fuiruim suggested you might be interested in examining this vial. It is a poison that was used to taint ore from the Nashkell mines, causing problems with the iron along the Sword Coast.~ GOTO Examine
END

APPEND _THALAN
IF ~~ THEN BEGIN Examine
  SAY ~A remarkable compound. It must have taken a skilled alchemist to concoct this. I may be able to formulate an antidote to salvage some of the current iron stocks, although I doubt it will be sufficient to resolve the crisis. Leave it with me, and I will contact Taerom if I have any success.~
  IF ~Global("D0TaintedOreQuest","GLOBAL",2)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",4)
AddexperienceParty(750)
TakePartyItem("_potn48")~ JOURNAL ~I showed a vial of mineral poison from the Nashkel mines to Thalantyr. He agreed to examine it and try to create an antidote. Hopefully this will have some effect on the iron crisis, although we cannot hope for much.~ EXIT
  IF ~!Global("D0TaintedOreQuest","GLOBAL",2)~ THEN DO ~SetGlobal("D0TaintedOreQuest","GLOBAL",3)
AddexperienceParty(750)
TakePartyItem("_potn48")~ JOURNAL ~I showed a vial of mineral poison from the Nashkel mines to Thalantyr. He agreed to examine it and try to create an antidote. Hopefully this will have some effect on the iron crisis, although we cannot hope for much.~ EXIT
END
END
<Moongaze> Luckily BWL has a very understanding and friendly admin.

 

With Quick-Reply you can write a post when viewing a topic without loading a new page. You can still use bulletin board code and smileys as you would in a normal post.

Warning: this topic has not been posted in for at least 120 days.
Unless you're sure you want to reply, please consider starting a new topic.

Name: Email:
Verification:
Type the letters shown in the picture
Listen to the letters / Request another image
Type the letters shown in the picture:
What color is grass?:
What is the seventh word in this sentence?:
What is five minus two (use the full word)?: