Author Topic: In Game Dialoque Problems  (Read 3541 times)

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
In Game Dialoque Problems
« on: September 10, 2004, 04:17:00 AM »
Okay here is my problem the code below is what i have and weidu compiles it all with no errors however when i try to speak with the creature he says his bit but it never seems to extern to my dialogue it just leaves the conversation.  The same thing happens when i re initiate conversation.

this also happens with the Interjections at the bottom

Can someone possibly tell me where i am going wrong - this is doing my head in!

bwcalumj is appended to the pdialog.2da in the tp2!

//code begins - dialogue removed


BEGIN bwcalumj
IF ~~ THEN BEGIN umar0 // from: 0.2
  SAY ~Say text la la la la la la!~
IF ~~ THEN DO ~SetGlobal("callumbless","GLOBAL",1)~ EXTERN ~SHAAVA01~ 4
END

IF ~~ THEN BEGIN umar2 // from: 0.2
  SAY ~Say text la la la la la la!~
IF ~~ THEN  EXIT
END

IF ~~ THEN BEGIN umar3 // from: 0.2
  SAY ~Say text la la la la la la!~
IF ~~ THEN EXTERN ~SHAAVA01~ callumvictor
END


///extending umar temple statue
ADD_TRANS_TRIGGER SHAAVA01 18 ~!InParty("bwcallum")~
ADD_TRANS_TRIGGER SHAAVA01 19 ~!InParty("bwcallum")~



EXTEND_BOTTOM SHAAVA01 18
IF ~InParty("bwcallum")
    !Dead("bwcallum")
    ~ THEN EXTERN ~bwcalumj~ umar2
END

EXTEND_BOTTOM SHAAVA01 19
IF ~InParty("bwcallum")
    !Dead("bwcallum")
    See("bwcallum")~ THEN EXTERN ~bwcalumj~ umar3
END


/////append shaava01
APPEND SHAAVA01
IF WEIGHT #-1 ~InParty("bwcallum")
    !Dead("bwcallum")
    See("bwcallum")
    Global("callumbless","GLOBAL",0)~ THEN BEGIN callumbless
    SAY ~Say text la la la la la la.~
    IF ~~ THEN EXTERN ~bwcalumj~ umar0
END


IF ~~ THEN BEGIN callumvictor // from: 0.2
  SAY ~Say text la la la la la la.~
IF ~~ THEN DO ~ SetGlobal("bwsuntemple","GLOBAL",1)~ EXIT
END
END ///end append





INTERJECT_COPY_TRANS BBEGG2 0 givetopoor
  == bwcalumj   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")Global("callumpoor","GLOBAL",0)~ THEN
    ~<CHARNAME> we should give to the poor whenever we can.  Even though we may have little to spare, in the end we will be rewarded in other ways.~
  == BBEGG2     IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")Global("callumpoor","GLOBAL",0)~ THEN
    ~That's right, the gods always look kindly on the generous souls!~
END

INTERJECT_COPY_TRANS BBEGG2 1 poorgotgold
  == bwcalumj   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")Global("callumpoor","GLOBAL",0)~ THEN
    ~<CHARNAME>, you will not regret this generosity, such good can only improve the Realms.~ DO ~SetGlobal("callumpoor","GLOBAL",1)~
END

INTERJECT_COPY_TRANS BBEGG2 3 giveanyway
  == bwcalumj   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")Global("callumpoor","GLOBAL",0)~ THEN
    ~<CHARNAME>, I believe you will come to regret this decision!~ DO ~SetGlobal("callumpoor","GLOBAL",1)~
END

INTERJECT_COPY_TRANS BEGGAR1 0 poorgive1
  == bwcalumj   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")Global("calbeggar1","GLOBAL",0)~ THEN
    ~Remember <CHARNAME> we will be rewarded for our good deeds.~
  == BEGGAR1   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")~ THEN
    ~Tis a reward indeed just to be as clean as ye are!~ DO ~SetGlobal("calbeggar1","GLOBAL",1)~
END

INTERJECT_COPY_TRANS BEGGAR1 10 poorgive2
  == bwcalumj   IF ~InParty("bwcallum")!Dead("bwcallum")See("bwcallum")~ THEN
    ~Good person, I hope you we find you well today?~
END


Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline cliffette

  • Timmins Tragic
  • Planewalker
  • *****
  • Posts: 547
  • Gender: Female
  • I still like Neighbours
Re: In Game Dialoque Problems
« Reply #1 on: September 10, 2004, 04:31:12 AM »
So Shaava01 talks, then it doesn't extern to bwcalumj?

Would getting rid of the tildes (~) from the "EXTERN ~bwcalumj~"  help? I've never used tildes there personally.

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #2 on: September 10, 2004, 04:40:59 AM »
I haven't tried it without the tildes to be honest but i was copying what had been used previously in other mods so i would not expect that to be too much of a problem and also it happens with the ICTs at the bottom too.

I do get a blank box where my dialogue should be and then get kicked from the conversation but i just can't figure out what the problem is!
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline Grim Squeaker

  • Fallen
  • Planewalker
  • *****
  • Posts: 1019
  • Gender: Male
Re: In Game Dialoque Problems
« Reply #3 on: September 10, 2004, 05:46:33 AM »
You aren't installing on an older version of Multi-install are you?  Coz that (Big black box with no new dialogue) was a bug with it.
"You alone can make my song take flight..."

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #4 on: September 10, 2004, 06:57:20 AM »
Multi -install?  Is this when weidu installs to multiple files at once? Or several BEGIN s are in one file?

I am on version 159 of weidu

Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline Rastor

  • Planewalker
  • *****
  • Posts: 271
  • Author of the book, "Being a Jerk for Dummies"
    • RPG Dungeon
Re: In Game Dialoque Problems
« Reply #5 on: September 10, 2004, 07:10:58 PM »
Multi-Install is a tool designed to make it easy to install multiple copies of BG2 onto your computer.

There's nothing there that would make SHAAVA01 state 4 EXTERN to anywhere in your NPC's dialogue.

Offline cliffette

  • Timmins Tragic
  • Planewalker
  • *****
  • Posts: 547
  • Gender: Female
  • I still like Neighbours
Re: In Game Dialoque Problems
« Reply #6 on: September 11, 2004, 01:48:26 AM »
Actually, how long are .dlg names allowed to be? Blue's tutorial mentions that they can only be 7 letters long, but SHAAVA01 is 8 letters, so that's still acceptable. Your bwcallumj is 9 letters long which might be pushing the envelope. Maybe it's just that you need to shorten the name to something 8 letters or below. Try it and see! :)

Offline SimDing0™

  • Back In Black
  • Global Moderator
  • Planewalker
  • *****
  • Posts: 3496
  • Gender: Male
  • Word Enhancer
Re: In Game Dialoque Problems
« Reply #7 on: September 11, 2004, 04:01:49 AM »
8 is the maximum for any IE file.

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #8 on: September 12, 2004, 09:06:30 AM »

bwcalumj is 8 letters, the globals use bwcallum (two L's) which might make things look confusing!  SHAAVA01 is the dialogue of an existing creature in the game so i don't think that would cause problems!

What happens is when the party initiates dialogue the creature saying the lines from the first APPEND but then instead of going to state umar0 in bwcalumj it just drops out of dialog altogether!

Anybody seen anything like this before, apart from the tildes being defunct i assume the rest of the code should work?

Its annoying to say the least!  I have a feeling the problem might be during the compiling as the same thing happens with the ICT's at the bottom though Weidu gives no error messages at all!

*sigh*
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline Avenger_teambg

  • Planewalker
  • *****
  • Posts: 399
Re: In Game Dialoque Problems
« Reply #9 on: September 12, 2004, 09:13:46 AM »
8 is the maximum for any IE file.
Not really, some lengths are 6 (.wed), and there is a little more restriction with music files too.

Offline jastey

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 1524
  • Gender: Female
Re: In Game Dialoque Problems
« Reply #10 on: September 19, 2004, 02:44:48 PM »
Hi Rabain!
Do you still have the problem? I also don't know the solution, the code looks OK! :(

Just to make sure: For trying out your dialogues, I guess you started the game and played them. Are you sure you had a "new" Callum present, I mean not a safegame with an already existing Callum, to make sure you are using the actual dialogue and script files? (This sounds so stupid, but sometimes it's one of these things that prevent the finding of the solution.)

Second: I would be strongly interested in seeing the SHAAVA01.d and bwcalumj.d taken out of the game after the mod is installed, if you haven't done that already. If the SHAAVA01 "callumbless" doesn't EXTERN to Callum's dialogues, you should see there where it actually points to. Or you can see whether bwcalumj.dlg is somehow broken. (BTW: If you want to address any question to me you could also post it at BW, as I'm usually not here. ;) )


And now some hints, from mod writer to mod writer ;)

You should change the TRANS_TRIGGER for shaava01 18 and 19 to ~OR(2) Dead("bwcallum)!InParty("bwcallum")~, otherwise there will be a "no valid link or reply" message in case of Callum being in the party but dead (and I would actually check "StateCheck("bwcallum",STATE_SLEEPING)", too.)


Here a suggestion: Why don't you use INTERSECT_COPY_TRANS for your interjection dialogues? Here's how I would have coded the interjections to shaava01 18 and 19:

Code: [Select]
ADD_TRANS_TRIGGER SHAAVA01 18 ~OR(3)
!InParty("bwcallum")
Dead("bwcallum") StateCheck("bwcallum",STATE_SLEEPING)~

I_C_T SHAAVA01 18 bwSomeCheckVariable
== bwcalumj IF ~InParty("bwcallum")
!Dead("bwcallum") !StateCheck("bwcallum",STATE_SLEEPING)~ THEN ~Say text la la la la la la!~
END

I don't say this is better, it's only a bit shorter and easier to "read". I use EXTEND_BOTTOM only, if I want to add an interjection dialogue with PC answers.

In your version, I would recommend to add a "COPY_TRANS", just to make sure whether some other mod has made changes to SHAAVA01 18 and 19, too:
Code: [Select]
IF ~~ THEN BEGIN umar2 // from: 0.2
  SAY ~Say text la la la la la la!~
COPY_TRANS SHAAVA01 18
END

Further:  From your posted dialogues I have the impression you don't do this, so I strongly recommend to you to use variables for all your interjection dialogues, to prevent the player from looping if your mod is installed twice (happens easily, if one version can't be uninstalled, happened to me once with my own mod.)


Hope I helped somehow...
jastey

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #11 on: September 19, 2004, 03:56:40 PM »

This is what appears in the SHAAVA01 decompiled file after the dialog has been loaded:

IF WEIGHT #2 /* Triggers after states #: 20 even though they appear after this state */
~Global("RitualDone","GLOBAL",1)
OR(2)
!Dead("SHADEL")
!Dead("SHALT01")
~ THEN BEGIN 18 // from:
  SAY #43029 /* ~The lessons are completed. One key has been given. All three keys shall thee need to form the Symbol of Amaunator and pass into the Darkness. The Dark Altar and Shade Lord must be destroyed. Such is the will of Amaunator.~ */
  IF ~!InParty("bwcallum")
~ THEN EXIT
  IF ~InParty("bwcallum")
!Dead("bwcallum")
~ THEN EXTERN ~BWCALUMJ~ 1
END

IF WEIGHT #3 /* Triggers after states #: 20 even though they appear after this state */
~Dead("SHALT01")
Dead("SHADEL")~ THEN BEGIN 19 // from:
  SAY #43829 /* ~Thy work is done. Amaunator's Blessing upon thee.~ */
  IF ~!InParty("bwcallum")
~ THEN EXIT
  IF ~InParty("bwcallum")
!Dead("bwcallum")
See("bwcallum")
~ THEN EXTERN ~BWCALUMJ~ 2
END

IF WEIGHT #0 ~InParty("bwcallum")
!Dead("bwcallum")
See("bwcallum")
Global("callumbless","GLOBAL",0)
~ THEN BEGIN 20 // from:
  SAY #74863 /* ~Favoured of Amaunator, prove yourself here in the eyes of the Sun Lord and know the Light will bless thee.~ */
  IF ~~ THEN EXTERN ~BWCALUMJ~ 0
END

IF ~~ THEN BEGIN 21 // from:
  SAY #74314 /* ~Favoured One, know that the Sun Lord is well pleased and gives his blessing. Continue thy travels in the name of Amaunator.~ */
  IF ~~ THEN DO ~SetGlobal("bwsuntemple","GLOBAL",1)
~ EXIT
END


And this is what appears in the decompiled bwcalumj file:

IF ~~ THEN BEGIN 0 // from:
  SAY #74862 /* ~Sun Lord I hear thee, let your will be done. I will cleanse these halls in your name!~ */
  IF ~~ THEN DO ~SetGlobal("callumbless","GLOBAL",1)
~ EXTERN ~SHAAVA01~ 4
END

IF ~~ THEN BEGIN 1 // from:
  SAY #74349 /* ~Thy will be done Amaunator. We will not rest until light once again blesses this ground!~ */
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 2 // from:
  SAY #74350 /* ~Once more the Sun bathes your Temple my Lord. We are victorious!~ */
  IF ~~ THEN EXTERN ~SHAAVA01~ 21
END



This is also a mini advertisement for Callum though there won't be so much of the thee's and thou's unless he is conversing with the Gods!

If I don't resolve this i am pretty much dead in water for the moment!
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline jastey

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 1524
  • Gender: Female
Re: In Game Dialoque Problems
« Reply #12 on: September 19, 2004, 04:23:57 PM »
So they look OK!
What was the problem again? You talk to the creature, you get your (weighted) dialogue, and then the dialogue jumps to Callum, but Callum doesn't say anything but has a black box? There is no "no valid link etc.", and it doesn't ignore the Callum input, either? So it actually tries to let Callum talk?

OK. Then maybe the problem is somewhere else. I would suggest to check the real basics, just to make sure!! (A la "if you have printing problems, please make sure the printer is turned on and connected to your computer"...) Please don't feel offended, but this is the way I would go now.
So:
-Are you sure the dialogue-file "BWCALUMJ" is the one assigned to Callum, no spelling errors in the interdia.2da, or .cre...
-(as I already mentioned above) Did you make sure you are not using an "old" Callum from some older savegame, from before the actual mod installation? What I did was: If I loaded a savegame where Ajantis was actually already present, but I wanted to check the new installed changes, I sent Ajantis away, then cheated CLUAConsole: CreateCreature("C#Ajant") to have the actual Ajantis-"version" ready for the dialogues I wanted to try.

I'll think of more possibilities... this problem can't be unsolvable! 

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #13 on: September 19, 2004, 05:11:13 PM »
Okay i think i see where the problem is, my APPEND to the pdialog.2da is not working.  Interdia.2da is working and the banters and the dialog in the bwcallum file works in game. 

Can anyone see anything wrong with my two APPEND's to pdialog.2da below?

Currently after installing the mod nothing appears in the pdialog file though interdia gets APPEND ed.  I have compared it to Ghareths tp2 and apart from the filenames it looks identical to me!


APPEND ~pdialog.2da~ // SOA append
~bwcallum         bwcalump               bwcalumj              bwcalumd~
UNLESS ~bwcallum~
UNLESS ~25POST~

APPEND ~pdialog.2da~ // TOB append
~bwcallum         bwcalump               bwcalumj              bwcalumd           calum25p           calum25j                  calum25d                  calum25~
UNLESS ~bwcallum~
UNLESS ~25POST~

APPEND ~interdia.2da~
~bwcallum    bbwcalum~
UNLESS ~bwcallum~
UNLESS ~25FILE~


APPEND ~interdia.2da~
~bwcallum    bbwcalum       bbwcal25~
UNLESS ~bwcallum~
IF     ~25FILE~
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline jastey

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 1524
  • Gender: Female
Re: In Game Dialoque Problems
« Reply #14 on: September 19, 2004, 05:32:02 PM »
Hmmmm..... I guess you have ToB installed? Then maybe you should allow the entry to be set: ;)

APPEND ~pdialog.2da~ // SOA append
~bwcallum         bwcalump               bwcalumj              bwcalumd~
UNLESS ~bwcallum~
UNLESS ~25POST~

APPEND ~pdialog.2da~ // TOB append
~bwcallum         bwcalump               bwcalumj              bwcalumd           calum25p           calum25j                  calum25d                  calum25~
UNLESS ~bwcallum~
IF ~25POST~


I'd say the problem is solved!  :)

Offline Ghreyfain

  • Moderator
  • Planewalker
  • *****
  • Posts: 4705
  • Gender: Male
    • Pocket Plane Group
Re: In Game Dialoque Problems
« Reply #15 on: September 19, 2004, 05:36:29 PM »
Or you could just forget about the entire 25post thing, which tends to only screw things up, as we found out with Kelsey.

Adding all the ToB-related lines to an SoA pdialog.2da does no harm.  Trying to patch on the ToB lines when you've already got your SoA lines in there is not quite as tricky these days, with new WeiDU features, but still not a necessary step.

Just append in all the 25 stuff and fuhgeddaboudit.
Earn Money Sleeping.

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #16 on: September 20, 2004, 02:25:03 AM »

I'll try it when i get home today.  Back to work now!  :(

Thanks guys!
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline jcompton

  • Niche Exploiter
  • Administrator
  • Planewalker
  • *****
  • Posts: 7246
Re: In Game Dialoque Problems
« Reply #17 on: September 20, 2004, 08:54:15 AM »
Or you could just forget about the entire 25post thing, which tends to only screw things up, as we found out with Kelsey.

You're misremembering.

There's nothing wrong with the entire 25post thing. The problem was that you bizarrely chose to put empty placeholders in there. :)
Cespenar says, "Kelsey and friends be at the Pocket Plane? Ohhh yesssss!" http://www.pocketplane.net

Offline Ghreyfain

  • Moderator
  • Planewalker
  • *****
  • Posts: 4705
  • Gender: Male
    • Pocket Plane Group
Re: In Game Dialoque Problems
« Reply #18 on: September 20, 2004, 12:02:43 PM »
Ohhhh, right.  *** or something, right?  Heh.
Earn Money Sleeping.

Offline Rabain

  • Planewalker
  • *****
  • Posts: 281
  • Gender: Male
  • Luck o' the Irish!
Re: In Game Dialoque Problems
« Reply #19 on: September 20, 2004, 02:01:33 PM »

Jastey - big gold star for you (http://www.blackwyrmlair.net/Forums/html/team_icons/goldmodder.gif)

Something as simple as changing UNESS to IF !  God that has been wrecking my head for...days!

THANK YOU!   :-*
Touchstone: Wild Elf Fighter
BG2CPM: Dialog Portraits for Everyone!
WTPFamiliars: A new version of the Find Familiar Spell
All at: Border Kingdoms

Offline jastey

  • Global Moderator
  • Planewalker
  • *****
  • Posts: 1524
  • Gender: Female
Re: In Game Dialoque Problems
« Reply #20 on: September 20, 2004, 02:33:42 PM »
Glad I could help!  :)

(With something as simple as this... Oh, no! Don't hit me!!  ;D )
Now I made you spell in capital letters, too  ;)

 

With Quick-Reply you can write a post when viewing a topic without loading a new page. You can still use bulletin board code and smileys as you would in a normal post.

Warning: this topic has not been posted in for at least 120 days.
Unless you're sure you want to reply, please consider starting a new topic.

Name: Email:
Verification:
Type the letters shown in the picture
Listen to the letters / Request another image
Type the letters shown in the picture:
What color is grass?:
What is the seventh word in this sentence?:
What is five minus two (use the full word)?: