Posted by: icelus
« on: March 11, 2006, 10:08:08 PM »Alright, was able to knock this one out, too.
tp2 code:
revised .d code:
tp2 code:
Code: [Select]
/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\
/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\
///// \\\\\
///// Wilton, Farmer Brun's Neighbor \\\\\
///// \\\\\
/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\
/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\/////\\\\\
BEGIN ~Wilton, Farmer Brun's Neighbor~
COPY_EXISTING WILTON.CRE OVERRIDE
ADD_CRE_ITEM ~CLCK01~ #1 #0 #0 ~NONE~ ~INV1 INV2~ // Adds Cloak of Protection +1
WRITE_ASCII 0x2cc ~UBWILTON~ // Assigns edited dialog file
WRITE_ASCII 0x280 ~Wilton~ // Assigns death variable
WRITE_SHORT 0x240 0x03 // Fix his morale setting
BUT_ONLY_IF_IT_CHANGES
COMPILE ~bg1ub/wilton/ubwilton.d~
<<<<<<<< .../bg1ub/ub_ar1403.baf
IF
Global("UB_WILTON_SPAWN","GLOBAL",0)
!Exists("Wilton")
!Dead("Wilton")
THEN
RESPONSE #100
CreateCreature("WILTON",[471.272],6)
SetGlobal("UB_WILTON_SPAWN","GLOBAL",1)
END
>>>>>>>>
EXTEND_BOTTOM AR1403.BCS ~.../bg1ub/ub_ar1403.baf~
revised .d code:
Code: [Select]
BEGIN ~UBWILTON~
IF ~Global("GaveAnkheg","GLOBAL",0)~ THEN BEGIN NotHelpedBrunYet
SAY #9036 /* ~Leave me be. I got nothin' for you.~ */
IF ~~ THEN EXIT
END
IF ~Global("GaveAnkheg","GLOBAL",1)
Global("UBWiltonGaveCloak","GLOBAL",0)~ THEN BEGIN BrunHelped
SAY #106 /* ~Stop a second there young'n, 'cause I heard what you gone and done for old Brun. It made me ashamed that I didn't try to help him myself. Good to know there's still someone willin' to go the extra mile, even for a stranger. I want you to have this heirloom of mine, because of what you did. Now my heirs didn't loom so big, but you ought to get more use out o' it than my mantle does. Folks like you make a jaded old man think there's still decent people out there.~ */
IF ~~ THEN DO ~GiveItem("CLCK01",LastTalkedToBy)
SetGlobal("UBWiltonGaveCloak","GLOBAL",1)
~ JOURNAL #5833 /* ~A man named Wilton gave me a reward for helping that old farmer, Brun. What goes around, comes around I guess.~ */ EXIT
END
IF ~Global("UBWiltonGaveCloak","GLOBAL",1)~ THEN BEGIN Ciao
SAY ~Sorry young'n, but I gotta lot of farming to do.~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END
IF ~StateCheck(Myself,STATE_CHARMED)~ THEN BEGIN Charmed
SAY #6432 /* ~Only thing exciting happenin' 'round these parts are the bandit raids. I'll warn ya now friend: I wouldn't try to mess with them bandits; I hear they're a real nasty bunch.~ */
IF ~~ THEN EXIT
END