Posted by: icelus
« on: March 18, 2006, 09:40:07 PM »OK, my bam problem is now fixed. It was indeed the compressed/uncompressed issue.
Many BG2 animations are compressed. BG1 does not support compression (it crashes when attempting to read such a BAM) so make sure you extract the BAMs uncompressed before trying to use then in BG1. NI will do this for you if you select the option to decompress the BAM before saving.
BEGIN ~Shilo Chen and the Ogre Magi~
COPY ~bg1ub/shilochen/CBRAC17.BAM~ ~override~
~bg1ub/shilochen/IBRAC17.BAM~ ~override~
COPY ~bg1ub/shilochen/UBGLOVE1.ITM~ ~override~
SAY NAME1 #6341
SAY NAME2 ~Gloves of Pick Pocketing~
SAY UNIDENTIFIED_DESC #6791
SAY IDENTIFIED_DESC ~Gloves of Pick Pocketing
A few years back Fong Moo a famous cutpurse, known in both Baldur's Gate and Athkatla, was found dead on the road between the Gate and Beregost. Seems he'd stolen an artifact from a powerful mage and tried escaping, with little success. His possessions went to a nephew, who took up the same trade as his uncle, and became especially good at pick pocketing. Whether these gloves were magical before falling into Fong's hands or if they are somehow imbued with the master's essence is not known.
STATISTICS
Pick Pocketing: +20% Bonus~
COPY_EXISTING OGREMA_A.CRE ~OVERRIDE/UBOGMA01.CRE~
WRITE_ASCII 0x280 ~UBOGMA01~
COPY_EXISTING OGREMA_B.CRE ~OVERRIDE/UBOGMA02.CRE~
WRITE_ASCII 0x280 ~UBOGMA02~
COPY_EXISTING OGREMA_C.CRE ~OVERRIDE/UBOGMA03.CRE~
WRITE_ASCII 0x280 ~UBOGMA03~
COPY_EXISTING AOLN.CRE ~OVERRIDE/UBSHILO.CRE~
SAY NAME1 #15640
SAY NAME2 #15685
WRITE_ASCII 0x250 ~~ #8
WRITE_ASCII 0x280 ~UBShilo~ #8
WRITE_ASCII 0x2cc ~ubshilo~ #8
ADD_CRE_ITEM ~UBGLOVE1~ #0 #0 #0 ~IDENTIFIED~ ~INV1 INV5~
COMPILE ~bg1ub/shilochen/ubshilo.d~
<<<<<<<< .../bg1ub/ub_ar0705sc.baf
IF
Global("CreateUBShiloChen","AR0705",0)
THEN
RESPONSE #100
CreateCreature("UBShilo",[606.967],10)
SetGlobal("CreateUBShiloChen","AR0705",1)
END
>>>>>>>>
EXTEND_BOTTOM AR0705.BCS ~.../bg1ub/ub_ar0705sc.baf~
<<<<<<<< .../bg1ub/ub_ar1900.baf
IF
GlobalGT("Chapter","GLOBAL",4)
Global("AcceptedUBShiloQuest","GLOBAL",1)
Global("CreateUBOgreMagi","AR1900",0)
THEN
RESPONSE #100
CreateCreature("UBOGMA01",[1736.2979],6)
CreateCreature("UBOGMA02",[1605.2915],14)
CreateCreature("UBOGMA03",[1754.2885],3)
SetGlobal("CreateUBOgreMagi","AR1900",1)
END
>>>>>>>>
EXTEND_BOTTOM AR1900.BCS ~.../bg1ub/ub_ar1900.baf~
BEGIN ~UBSHILO~
IF ~Alignment(LastTalkedToBy,MASK_EVIL)~ THEN BEGIN 0 // from:
SAY #15182 /* ~I can smell the city on you.~ */
IF ~~ THEN DO ~~ EXIT
END
IF ~Global("AcceptedUBShiloQuest","GLOBAL",0)
!Alignment(LastTalkedToBy(),MASK_EVIL)~ THEN BEGIN 1 // from:
SAY #15183 /* ~There are some ogre-magi causing trouble in the southwest corner of the Wood of Sharp Teeth. If you could clear them out before they do too much damage, I'd be very grateful. In the meantime, I'll try to find some other adventurers to help out in case things start getting too rough..~ */
IF ~~ THEN DO ~SetGlobal("AcceptedUBShiloQuest","GLOBAL",1)~ JOURNAL #15772 /* ~Shilo Chen, a ranger from the Wood of Sharp Teeth, is currently seeking help in Baldur's Gate. A group of ogre-magi is killing off the wildlife in the wood's southwest corner. He has asked me to go there and see what I can do. If he can find any other willing adventurers, he'll send them as reinforcements. ~ */ EXIT
END
IF ~Global("AcceptedUBShiloQuest","GLOBAL",1)
!Dead("UBOGMA01")
!Dead("UBOGMA02")
!Dead("UBOGMA03")~ THEN BEGIN 2 // from:
SAY #15184 /* ~How can you stay in this foul city when the forest is in danger??~ */
IF ~~ THEN DO ~~ EXIT
END
IF ~Dead("UBOGMA01")
Dead("UBOGMA02")
Dead("UBOGMA03")~ THEN BEGIN 3 // from:
SAY #15185 /* ~The hawks tell me that you cleared away the ogre-magi all by yourselves. I am impressed with your valor. Here, let me give you these fine gloves as a token of my appreciation. They are so supple that you can feel even the downiest feather as it brushes against your palm.~ */
IF ~~ THEN DO ~AddexperienceParty(750)
ReputationInc(1)
GiveItem("UBGLOVE1",LastTalkedToBy)
SetGlobal("AcceptedUBShiloQuest","GLOBAL",2)
EscapeArea()~ JOURNAL ~Having defeated the ogre-magi in the Wood of Sharp Teeth, Shilo Chen has rewarded us handsomely.~ EXIT
END
IF ~StateCheck(Myself,8192)~ THEN BEGIN 4 // from:
SAY #15186 /* ~You city dwellers are all the same!~ */
IF ~~ THEN DO ~~ EXIT
END
Why would a Ranger be walking around with a pair of gloves of pickpocketing?Because Fong Moo's nephew got caught nicking the goods from one too many people, had the law sent after him, and decided it'd be best to lay low in the hills outside of town for a while. Too bad he never saw that bear....