Feature Request: More Things Accepted by STR_VAR

[Mike1072]

Can STR_VAR be modified to accept .tra references?

[the bigg]

It's possible, but it'd mess up traify (the same bug happens with SPRINT).

[Mike1072]

I didn't feel like causing a fuss before, but I do now. I think this downside would be acceptable.  Anyone else have an opinion?

I'd like to use this feature on a function that deals with adding strings to dialog.tlk as part of editing a 2DA file.  I can imagine other hypothetical cases where this could be useful as well.

[the bigg]

Anyone else have an opinion?

I do, and my opinion is "don't make traify even buggier". The closest I can do is to allow @variable in both .d and .tp*:

SET x = 5 + y
<...>
SAY NAME @x

however, expressions like @(x + 2) are not allowed.

[Mike1072]

Ugh, I give up.  Functions are not always better than macros, even when they should be.

[Miloch]

I thought SPRINT var @n worked now, or is it some other workaround?

[the bigg]

SPRINT VAR @n always worked (unfortunately).

[Galactygon]

The closest I can do is to allow @variable in both .d and .tp*:

SET x = 5 + y
<...>
SAY NAME @x

however, expressions like @(x + 2) are not allowed.

I would like to make @variable a request; it would save me hundreds of lines of code.

-Galactygon

[Mike1072]

I ended up creating this function to help do what I needed.

Code: [Select]

DEFINE_PATCH_FUNCTION ~REF2STR~ // given tra reference, strref, or string, returns appropriate string
  STR_VAR ref = ~~ // e.g. ~@123~, ~#9241~, or ~Anything that isn't numbers preceded by @ or # is a string, like this is!~
  RET str
BEGIN
  PATCH_IF ((~%ref%~ STRING_MATCHES_REGEXP ~[@#]-?[0-9]+~) == 0) BEGIN
    INNER_ACTION BEGIN
      <<<<<<<< .../inlined/mi_ref2str.tph
        OUTER_SPRINT str %ref%
      >>>>>>>>
      COPY - ~.../inlined/mi_ref2str.tph~ ~.../inlined/mi_ref2str.tph~
        EVALUATE_BUFFER
      REINCLUDE ~.../inlined/mi_ref2str.tph~
    END
  END
  ELSE BEGIN
    TEXT_SPRINT str ~%ref%~
  END
END
Then I could sneak tra references and strrefs into functions inside of a string.

[the bigg]

Done. Can use all of @~var~, @"var", @%var%, @~%var%~ and @"%var%" in .d, .baf and .tp*.

Code: [Select]

<<<<<<<< a.d
BEGIN asd
IF ~~ THEN foo
 SAY @~%asd%~
IF ~~ THEN EXIT
END
>>>>>>>>

<<<<<<<< a.baf
IF
  True()
THEN
  RESPONSE #100
    DisplayStringHead(Myself,@%asd%)
END
>>>>>>>>

OUTER_SET asd=0
COMPILE ~a.d~ ~a.baf~

PRINT @"asd"


[Galactygon]

Thanks. Is there any way to check if %variable% exists in the .tra file?

Code: [Select]

PATCH_IF TRA_ENTRY_EXISTS variable BEGIN
SAY 0x00 @variable
END

-Galactygon

[the bigg]

Sure, can do.

TRA_ENTRY_EXISTS (variable_name tra_file...)

[Galactygon]

Thanks.

-Galactygon

[the bigg]

I had to change the syntax slightly because I HATE FRENCH PEOPLE. Rather than the sleek @"foo" you need to write (AT "foo").

Sample code:

Code: [Select]

<<<<<<<< standard.tra
@0 = ~lolwut?~
>>>>>>>>

LOAD_TRA standard.tra

<<<<<<<< has_zero.tra
@0 = ~lolwat?~
>>>>>>>>

<<<<<<<< no_zero.tra
>>>>>>>>

OUTER_SET asd=0
OUTER_SET foo=1

PRINT (AT asd) // @var-like construct works in .tp*

<<<<<<<< test.baf
IF
THEN
RESPONSE #100
DisplayString(Myself,(AT "asd")) // @var-like construct works in .baf
END
>>>>>>>>

<<<<<<<< test.d
BEGIN asd
IF ~~ THEN BEGIN S
  SAY (AT asd) // @var-like construct works in .d
++ (AT asd) EXIT
END
>>>>>>>>

COMPILE ~test.baf~ ~test.d~


ACTION_IF TRA_ENTRY_EXISTS (0) THEN BEGIN // true: @0 is loaded
PRINT ~ok~
END

ACTION_IF TRA_ENTRY_EXISTS (asd) THEN BEGIN // true: asd = 0 and @0 is loaded
PRINT ~ok~
END

ACTION_IF TRA_ENTRY_EXISTS (asd ~has_zero.tra~) THEN BEGIN // true: asd = 0 and @0 is in has_zero.tra
PRINT ~ok~
END

ACTION_IF TRA_ENTRY_EXISTS (asd ~has_zero.tra~ ~missing.tra~) THEN BEGIN // true: asd = 0 and one of the listed files contains @0
PRINT ~ok~
END

ACTION_IF TRA_ENTRY_EXISTS (asd not_zero.tra) THEN BEGIN // false: asd = 0 and @0 is not in not_zero.tra
PRINT ~nok~
END

ACTION_IF TRA_ENTRY_EXISTS (asd missing.tra) THEN BEGIN // false: missing.tra doesn't exist, thus it doesn't contain @0
PRINT ~nok~
END

ACTION_IF TRA_ENTRY_EXISTS (foo) THEN BEGIN // false: foo = 1 and @1 isn't currently defined
PRINT ~nok~
END

ACTION_IF TRA_ENTRY_EXISTS (psd) THEN BEGIN // false: psd isn't a valid integer
PRINT ~nok~
END


[Galactygon]

Can you add this one too?

APPEND ~SOME2DA.2da~ ~Test @1~

-Galactygon

[the bigg]

No, use APPEND + COPY_EXISTING REPLACE.

[Galactygon]

I know. That's 4 lines of code instead of 1.

-Galactygon

[the bigg]

Actually, 3 lines (or even 2 with OUTER_SPRINT + APPEND) 

However, I can't code this in a satisfactory way - I can certainly add it as a special case to APPEND (and/or other individual commands), but (because of limitations in OCaml) I can't add it to the generic evaluate_variables function (which would be the natural solution to make that kind of evaluation generic).